From 22c2246abed5fd37f86cc181c7b2ef395e547872 Mon Sep 17 00:00:00 2001
From: David P <megver83@parabola.nu>
Date: Wed, 19 Feb 2020 21:21:55 -0300
Subject: rmpkg: pcr/sysvinit

it's on [nonsystemd] now

Signed-off-by: David P <megver83@parabola.nu>
---
 pcr/sysvinit/PKGBUILD | 58 ---------------------------------------------------
 1 file changed, 58 deletions(-)
 delete mode 100644 pcr/sysvinit/PKGBUILD

diff --git a/pcr/sysvinit/PKGBUILD b/pcr/sysvinit/PKGBUILD
deleted file mode 100644
index ee01d5288..000000000
--- a/pcr/sysvinit/PKGBUILD
+++ /dev/null
@@ -1,58 +0,0 @@
-# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
-# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
-# Maintainer (Manjaro): artoo <artoo@manjaro.org>
-# Contributor (Manjaro): Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
-# Maintainer (Arch Linux): Eric Belanger <eric@archlinux.org>
-
-pkgname=sysvinit
-pkgver=2.90
-pkgrel=1
-pkgdesc='Linux System V Init'
-url='http://www.nongnu.org/sysvinit/'
-arch=('i686' 'x86_64' 'armv7h')
-license=('GPL')
-depends=('glibc')
-provides=('init')
-conflicts=('init')
-
-validpgpkeys=('146BF1D0D20B006B10299B4CFA3EC79A4C0C11CC') # Jesse Smith <jsmith@resonatingmedia.com>
-source=("https://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig})
-sha256sums=('114cffc8ef514a38b9916de2050bb6d73b43dff7afd05aee6b09d2f6cea7664e'
-            'SKIP')
-
-build() {
-    cd "$srcdir/$pkgname-$pkgver"
-    make
-}
-
-package() {
-    cd "$srcdir/$pkgname-$pkgver"
-
-    mkdir -p "$pkgdir/usr/bin"
-    ln -s usr/bin "$pkgdir/bin"
-    ln -s usr/bin "$pkgdir/sbin"
-    make ROOT="$pkgdir" install
-    rm "$pkgdir/bin" "$pkgdir/sbin"
-
-    local rmprogs=(
-        # provided by util-linux
-        last
-        lastb
-        mesg
-        sulogin
-        utmpdump
-        wall
-        # provided by procps-ng
-        pidof
-    )
-    cd "$pkgdir"
-    local prog
-    for prog in "${rmprogs[@]}"; do
-        rm usr/bin/"$prog" usr/share/man/man?/"$prog".?
-    done
-
-    # old Arch Linux sysvinit would have split out fstab-decode,
-    # killall5, and bootlogd into a separate sysvinit-tools package.
-    # Unfortunately, because sysvinit-tools provided pidof, procps-ng
-    # still conflicts=(sysvinit-tools).
-}
-- 
cgit v1.2.2