From 4fa5fca32cb65760b1df29dcd05823cf7fbaee09 Mon Sep 17 00:00:00 2001
From: bill-auger <mr.j.spam.me@gmail.com>
Date: Fri, 5 Mar 2021 23:05:43 -0500
Subject: [kdenlive]: add package

---
 libre/kdenlive/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 libre/kdenlive/PKGBUILD

diff --git a/libre/kdenlive/PKGBUILD b/libre/kdenlive/PKGBUILD
new file mode 100644
index 000000000..baeb96de5
--- /dev/null
+++ b/libre/kdenlive/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Zuf <kontakt.zuf@gmail.com>
+# Contributor: Darwin Bautista <djclue917@gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
+
+
+# parabola changes and rationale:
+# - arch package links to qt5-webengine
+# - no changes necessary - simply rebuild without qt5-webengine in the environment
+
+
+pkgname=kdenlive
+pkgver=20.12.3
+pkgrel=1
+pkgrel+=.parabola1
+pkgdesc="A non-linear video editor for Linux using the MLT video framework"
+arch=(x86_64)
+url="https://www.kdenlive.org/"
+license=(GPL)
+groups=(kde-applications kde-multimedia)
+depends=(knewstuff knotifyconfig kfilemetadata purpose mlt rttr breeze-icons frei0r-plugins)
+makedepends=(extra-cmake-modules kdoctools v4l-utils)
+optdepends=('ffmpeg: for FFmpeg plugin'
+            'cdrtools: for creation of DVD ISO images'
+            'dvdauthor: for creation of DVD'
+            'dvgrab: for firewire capture'
+            'recordmydesktop: for screen capture'
+            'xine-ui: for DVD preview'
+            'vlc: for DVD preview'
+            'opencv: for motion tracking'
+            'plasma-desktop: theme configuration')
+source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('8d9f94699befc59b0a410d99dcafd445f33126678c18d859df4fceb553a88586'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}
-- 
cgit v1.2.2