From 5b245d505c1f3fcb404634152f4baa20134fa321 Mon Sep 17 00:00:00 2001
From: Omar Vega Ramos <ovruni@gnu.org.pe>
Date: Sun, 13 Sep 2015 04:00:01 -0500
Subject: java-commons-codec: add new package to [pcr]

---
 pcr/java-commons-codec/PKGBUILD | 44 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 pcr/java-commons-codec/PKGBUILD

(limited to 'pcr/java-commons-codec')

diff --git a/pcr/java-commons-codec/PKGBUILD b/pcr/java-commons-codec/PKGBUILD
new file mode 100644
index 000000000..790170371
--- /dev/null
+++ b/pcr/java-commons-codec/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_pkgname=commons-codec
+pkgname=java-${_pkgname}
+pkgver=1.10
+pkgrel=1
+pkgdesc="Encoder and decoders such as Base64 and hexadecimal codec"
+arch=('any')
+url="http://commons.apache.org/codec/"
+license=('APACHE')
+depends=('java-runtime')
+makedepends=('apache-ant' 'jh')
+source=("http://archive.apache.org/dist/commons/codec/source/${_pkgname}-${pkgver}-src.tar.gz")
+md5sums=('ea7c015a2c7b641cd11298ed94d992c7')
+
+prepare() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+  sed -i 's/1\.9/1\.10/g' default.properties
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+  ant dist
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "dist/docs/api" "${pkgdir}/usr/share/doc/${pkgname}"
+
+  # Install Maven artifacts
+  export DESTDIR=${pkgdir}
+  jh mvn-install ${_pkgname} ${_pkgname} ${pkgver} \
+    "${srcdir}/${_pkgname}-${pkgver}-src/pom.xml" \
+    "${srcdir}/${_pkgname}-${pkgver}-src/dist/${_pkgname}-${pkgver}-SNAPSHOT.jar" \
+    "${_pkgname}.jar"
+  ln -s "/usr/share/java/${_pkgname}.jar" \
+    "${pkgdir}/usr/share/java/${_pkgname}-${pkgver}.jar"
+}
\ No newline at end of file
-- 
cgit v1.2.2