From a3066d27a04e5ffd8ccf75409dbec924df1519df Mon Sep 17 00:00:00 2001
From: Guest One <theguestone@gmail.com>
Date: Mon, 20 May 2013 21:36:50 +0200
Subject: added new package nicotine 1.2.16-1

---
 pcr/nicotine/PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 pcr/nicotine/PKGBUILD

(limited to 'pcr/nicotine')

diff --git a/pcr/nicotine/PKGBUILD b/pcr/nicotine/PKGBUILD
new file mode 100644
index 000000000..b0bd552b4
--- /dev/null
+++ b/pcr/nicotine/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Guest One <theguestone at gmail dot com>
+
+pkgname=nicotine
+pkgver=1.2.16
+pkgrel=1
+pkgdesc="Soulseek music-sharing client, written in python"
+arch=('i686')
+url='http://sourceforge.net/projects/nicotine-plus/'
+license=('GPL')
+depends=('pygtk' 'mutagen' 'python2-sexy')
+makedepends=('setconf')
+optdepends=('python2-geoip: to enable Geographical blocker')
+source=("http://downloads.sourceforge.net/project/nicotine-plus/nicotine-plus/${pkgver}/${pkgname}+-${pkgver}.tar.bz2")
+sha256sums=('71e5b33e273daaf072dbf63839536c14d7ead9d149323d50eee09f7429e34c1d')
+
+prepare() {
+  cd "$srcdir/${pkgname}+-$pkgver"
+
+  # Fix for FS#22476
+  setconf files/nicotine.desktop Icon nicotine-plus-32px
+
+  # Python fix
+  sed -i -e 's|/usr/bin/env python|/usr/bin/env python2|' \
+    -e 's|/usr/bin/python|/usr/bin/python2|' pynicotine/{,gtkgui/}*.py
+} 
+
+build() {
+  cd "$srcdir/${pkgname}+-$pkgver/trayicon"
+
+  python2 autogen.py
+  make 
+}
+
+package() {
+  cd "$srcdir/${pkgname}+-$pkgver"
+
+  python2 setup.py install --root="$pkgdir"
+  cd trayicon
+  make DESTDIR="$pkgdir" install 
+  ln -s nicotine.py "$pkgdir/usr/bin/nicotine"
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v1.2.2