# $Id: PKGBUILD 182407 2013-04-10 07:34:20Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=binutils
_target="xtensa-unknown-elf"

pkgname=${_target}-${_pkgname}
pkgver=2.23.2
pkgrel=2.5
pkgdesc="A set of programs to assemble and manipulate binary and object files for the Xtensa architecture"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/binutils/"
license=('GPL')
groups=("${_target}-base-devel")
depends=('glibc>=2.17' 'zlib')
options=('!libtool' '!distcc' '!ccache')
install=${_target}-binutils.install
source=(ftp://ftp.gnu.org/gnu/binutils/binutils-${pkgver}.tar.bz2{,.sig}
        https://raw.github.com/qca/open-ath9k-htc-firmware/1.3.2/local/patches/binutils.patch
        binutils-2.23.2-texinfo-5.0.patch)
md5sums=('4f8fa651e35ef262edc01d60fb45702e'
         'dfde4428f08d91f309cdcfe92bf28d08'
         '7077126d96e9a755a0eaddb5505efe68'
         '34e439ce23213a91e2af872dfbb5094c')

prepare() {
  cd ${srcdir}/binutils-${pkgver}

  # http://sourceware.org/git/?p=binutils.git;a=patch;h=e02bf935
  # http://sourceware.org/git/?p=binutils.git;a=patch;h=935f8542
  patch -p1 -i ${srcdir}/binutils-2.23.2-texinfo-5.0.patch

  # open-ath9k-htc-firmware patch
  patch -p1 -i ${srcdir}/binutils.patch

  # hack! - libiberty configure tests for header files using "$CPP $CPPFLAGS"
  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure

  mkdir ${srcdir}/binutils-build
}

build() {
  cd ${srcdir}/binutils-build

  ${srcdir}/binutils-${pkgver}/configure --prefix=/usr \
    --target=${_target} \
    --disable-nls \
    --with-lib-path=/usr/lib:/usr/local/lib \
    --with-bugurl=https://labs.parabola.nu/ \
    --enable-shared \
    --disable-werror --disable-multilib

  # check the host environment and makes sure all the necessary tools are available
  make configure-host

  make tooldir=/usr
}

package() {
  cd ${srcdir}/binutils-build
  make prefix=${pkgdir}/usr tooldir=${pkgdir}/usr install

  # Remove unwanted files
  rm ${pkgdir}/usr/share/man/man1/${_target}-{dlltool,nlmconv,windres,windmc}*

  # Remove unnecessary files and folders
  rm $pkgdir/usr/bin/{a{r,s},nm,obj{copy,dump},ranlib,strip}
  rm $pkgdir/usr/lib/libiberty.a
  rm $pkgdir/usr/$CHOST/${_target}/include/* && rmdir $pkgdir/usr/$CHOST/${_target}/include
  rm $pkgdir/usr/share/info/* && rmdir $pkgdir/usr/share/info
}