# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=closure-compiler
pkgver=20131118
pkgdesc="A JavaScript optimizing compiler."
url="https://code.google.com/closure/compiler/"
license=('Apache')

pkgrel=1
arch=('any')
depends=('java-runtime' 'sh')
makedepends=(
  'apache-ant'
  #'java-args4j' # does not exist
  #'google-caja' # does not exist
  #'java-guava' # does not build
  'java-jarjar'
  'java-json'
  #'java-jsr305' # does not exist
  'junit'
  #'java-protobuf' # does not build
  #'maven-ant-tasks' # does not exist
  'jh'
)

source=("libre://$pkgname-$pkgver.tar.gz" 'closure-compiler.sh')
md5sums=('0fceda3f4d43a6d266f9888e7683bdc9'
         'd4ead4585fcc7039d3c32eb5c4491bb9')

mksource=("$pkgname-$pkgver::git+https://code.google.com/p/closure-compiler/#tag=v${pkgver}")
mkmd5sums=('SKIP')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ln -sf /opt/apache-ant/lib/ant.jar          lib/ant.jar
  ln -sf /opt/apache-ant/lib/ant-launcher.jar lib/ant-launcher.jar
  #ln -sf /usr/share/java/args4.jar            lib/args4j.jar
  #ln -sf /usr/share/java/caja-r4314.jar       lib/caja-r4314.jar
  #ln -sf /usr/share/java/guava.jar            lib/guava.jar
  ln -sf /usr/share/java/jarjar.jar           lib/jarjar.jar
  ln -sf /usr/share/java/json.jar             lib/json.jar
  #ln -sf /usr/share/java/jsr305.jar           lib/jsr305.jar
  ln -sf /usr/share/java/junit.jar            lib/junit.jar
  #ln -sf /usr/share/java/protobuf.jar         lib/protobuf-java.jar
  #ln -sf /...                                 tools/maven-ant-tasks-2.1.3.jar

  sed -i "
/<target name=\"relversion\">/,/<\/target>/ {
  s/executable=\"git\"/executable=\"echo\"/
  /<arg/d
  /<\/exec>/i<arg value=\"v${pkgver}\" />
}" build.xml

  ant jar pom
}

package() {
  cd "$srcdir"
  install -Dm755 closure-compiler.sh  "$pkgdir"/usr/bin/closure-compiler

  cd "$srcdir/$pkgname-$pkgver"
  DESTDIR="$pkgdir" jh mvn-install \
    com.google.javascript closure-compiler v${pkgver} \
    build/pom.xml build/compiler.jar \
    closure-compiler.jar
}