# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=java-commons-bsf2
pkgver=2.4.0
url="https://commons.apache.org/proper/commons-bsf/"
license=('Apache')
pkgdesc="Bean Scripting Framework"

pkgrel=1
arch=('any')
depends=('java-commons-logging')
makedepends=('apache-ant')

_mirror=http://archive.apache.org/dist
source=($_mirror/commons/bsf/source/bsf-src-$pkgver.tar.gz
  build-properties.xml::"https://svn.apache.org/viewvc/commons/proper/bsf/tags/bsf-2.4.0/build-properties.xml?view=co&content-type=text%2Fplain"
)

declare -A _opts
#_opts[jacl]="/usr/share/java/jacl.jar"
_opts[jython]="/opt/jython/jython.jar"
#_opts[nexrexx]="/usr/share/java/nexrexx.jar"
_opts[java-rhino]="/usr/share/java/js.jar"
_opts[xalan-java]="/usr/share/java/xalan.jar"
_opts[junit]="/usr/share/java/junit.jar"

for pkg in "${!_opts[@]}"; do
  optdepends+=("$pkg")
  makedepends+=("$pkg")
  _jars+="${_opts[$pkg]} "
done

prepare() {
  cd "${srcdir}/bsf-${pkgver}"
  rm lib/*.jar
}

build() {
  cd "${srcdir}/bsf-${pkgver}"

  for jar in $_jars; do
	  ln -s "$jar" lib/
  done

  # Adjust it to work with jython 2.5+
  sed -i 's/PyJavaInstance/PyJavaType/g' src/org/apache/bsf/engines/jython/*

  ln -sf ../build-properties.xml ./
  ant jar
}

package() {
  cd "${srcdir}/bsf-${pkgver}"
  install -Dm644 build/lib/bsf.jar "$pkgdir"/usr/share/java/bsf-$pkgver.jar
  ln -s bsf-$pkgver.jar "$pkgdir"/usr/share/java/bsf2.jar
}

md5sums=('7e58b2a009c0f70ab36bbef420b25c07'
         'd7180c2b95f1a5424f785a2482260eaa')