# $Id: PKGBUILD 117596 2014-08-19 02:28:18Z fyan $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgbasename=mesa-demos
pkgname=lib32-$_pkgbasename
pkgver=8.2.0
pkgrel=2.parabola1
arch=(x86_64)
pkgdesc="Mesa demos and tools (32-bit), without nonfree demos"
url="http://mesa3d.sourceforge.net"
license=('custom')
replaces=('lib32-mesa-demos-libre')
conflicts=('lib32-mesa-demos-libre')
depends=('lib32-libgl' 'lib32-glew' 'mesa-demos')
makedepends=(gcc-multilib 'lib32-mesa' 'lib32-glew')
source=(https://repo.parabola.nu/other/mesa-demos-libre/mesa-demos-libre-${pkgver}.tar.bz2
        libre.patch)
md5sums=('67cd419bd5bbaa6436ad98a703d30441'
         'e986d07f36931e895bdbd9c83ed260c8')

prepare() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  # remove nonfree demos references (pointblast and spriteblast)
  patch -Np1 -i ../libre.patch
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "${srcdir}/mesa-demos-${pkgver}"
  ./configure --prefix=/usr 

  make
}

package() {
  depends=('lib32-glew' mesa-demos)

  cd "${srcdir}/mesa-demos-${pkgver}"
  make DESTDIR="${pkgdir}" install

  for i in "$pkgdir/usr/bin/"*; do
    mv "$i" "$i"32
  done

  rm -r "$pkgdir/usr/share/mesa-demos"

  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}