# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=lib32-$pkgbase-$_pkgname
pkgver=12.0.1
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library and ICD loader (32-bit)'
arch=('x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase-$_pkgname" "lib32-$pkgbase" 'lib32-libclc' 'lib32-libgcrypt' 'lib32-clang')
# please use libretools, install "multilib-devel" on chroot and add
#  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
makedepends=('python2-mako' 'dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2' 'llvm')
provides=("lib32-$_pkgname" 'lib32-opencl-icd-loader')
conflicts=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx' 'lib32-ocl-icd')
replaces=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig}
        remove-libpthread-stubs.patch
        0001-st-mesa-fix-reference-counting-bug-in-st_vdpau.patch
        0002-vl-dri3-fix-a-memory-leak-from-front-buffer.patch
        0001-Mesa-dev-st_glsl_to_tgsi-overlord-fix.patch
        0001-i965-import-prime-buffers-in-the-current-context-not.patch)
sha512sums=('11898336478d1f5bd3946d695b9599647c0b9084ad8890b4fa89daa922a217e5ca6d8b72f5801e362c3dd7723382f2daaa655b54f65a6d088ad8cfdb85f10023'
            'SKIP'
            '6349de16a2a11b8540d82a78cd15574ea92e0a22f2e184b93311060f72cc3749efba67be464a1b399493035c6e389017d5631b0be2e8ef5da115b137e26c33df'
            '499312eb048e32b27820eebeb243df926226f3c2247bfc9b19b28664eaffc7e524cc1dc760d701159a46f37be46e49e956b27de473c465cecbdf0db6d6b97fe0'
            'e8b6c75565b7f72f5bc073469fef50e2b04311dc235885f69ad15591e338601273dec99bfd8cbb85f0cc5b3ecf4e4ac8c6ef64225e2ed68504081af3944f88a8'
            'fd677879e97f7d30346ef9c41e89770e06e4714b0e74c7bb3d88984038e2fb3cc7f7fb6df59469527ba2c07f8bf51959f65e8dd6dfceea9e400b44157308b816'
            '8b6c5eb3024ae5095fbb86e07aa578ede106844388077b5b9d2e9b5822640424be308e34d67daff44b0c25624f2b4ff1e67fc5d21cf5dfaa07b760be2cbd1531')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

prepare() {
  cd $srcdir/$pkgbase-$pkgver

  # Fix detection of libLLVM when builds with CMake
  sed -i 's/LLVM_SO_NAME=.*/LLVM_SO_NAME=LLVM/' configure

  # Now mesa checks for libpthread-stubs - so remove the check
  patch -Np1 -i ../remove-libpthread-stubs.patch

  # fix memory leaks - merged upstream
  patch -Np1 -i ../0001-st-mesa-fix-reference-counting-bug-in-st_vdpau.patch
  patch -Np1 -i ../0002-vl-dri3-fix-a-memory-leak-from-front-buffer.patch
  # fix rendering in some games - merged upstream
  patch -Np1 -i ../0001-Mesa-dev-st_glsl_to_tgsi-overlord-fix.patch
  # fix https://bugs.freedesktop.org/show_bug.cgi?id=71759 / FS#50240
  # reverted because of it segfault X with modesetting/intel 
  #patch -Np1 -i ../0001-i965-import-prime-buffers-in-the-current-context-not.patch

  autoreconf -fiv
}

build() {
  cd $srcdir/$pkgbase-$pkgver

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  export LLVM_CONFIG='/usr/bin/llvm-config32'
  if [[ $(uname -o) == GNU/Hurd ]]; then
    export _HOST=i686-unknown-gnu
  elif [[ $(uname -o) == GNU/Linux ]]; then
    export _HOST=i686-unknown-linux-gnu
  elif [[ $(uname -o) == GNU/kFreeBSD ]]; then
    export _HOST=i686-unknown-kfreebsd-gnu
  fi

  ./configure --prefix=/usr --libdir=/usr/lib32 --host=$_HOST \
    --sysconfdir=/etc \
    --enable-llvm-shared-libs \
    --enable-opencl \
    --with-clang-libdir=/usr/lib32
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/$pkgbase-$pkgver

  install -vm755 -d $pkgdir/usr/lib32/
  cp -rv $srcdir/fakeinstall/usr/lib32/libOpenCL* $pkgdir/usr/lib32/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: