# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=mesa
pkgname=lib32-opencl-$pkgbase
pkgver=12.0.2
pkgrel=1
pkgdesc='OpenCL support for mesa drivers (32-bit)'
arch=('x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("opencl-$pkgbase" "lib32-$pkgbase-libgl" "lib32-$pkgbase=$pkgver" 'lib32-opencl-icd-loader' 'lib32-libclc' 'lib32-libgcrypt' 'lib32-clang')
optdepends=('opencl-headers: headers necessary for OpenCL development')
# please use libretools, install "multilib-devel" on chroot and add
#  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
makedepends=('python2-mako' 'dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2' 'llvm')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig}
        remove-libpthread-stubs.patch)
sha512sums=('61fcbc3af16fff53f4877c5731c10fffa32a75c2eda9706d27ffdf00bd65a2c36b4ece165049b02c7269088f0755d93f6646ebc031d4b3fc838e316a5fcb2617'
            'SKIP'
            '6349de16a2a11b8540d82a78cd15574ea92e0a22f2e184b93311060f72cc3749efba67be464a1b399493035c6e389017d5631b0be2e8ef5da115b137e26c33df')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

prepare() {
  cd $srcdir/$pkgbase-$pkgver

  # Fix detection of libLLVM when builds with CMake
  sed -i 's/LLVM_SO_NAME=.*/LLVM_SO_NAME=LLVM/' configure

  # Now mesa checks for libpthread-stubs - so remove the check
  patch -Np1 -i ../remove-libpthread-stubs.patch

  autoreconf -fiv
}

build() {
  cd $srcdir/$pkgbase-$pkgver

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  export LLVM_CONFIG='/usr/bin/llvm-config32'
  if [[ $(uname -o) == GNU/Hurd ]]; then
    export _HOST=i686-unknown-gnu
  elif [[ $(uname -o) == GNU/Linux ]]; then
    export _HOST=i686-unknown-linux-gnu
  elif [[ $(uname -o) == GNU/kFreeBSD ]]; then
    export _HOST=i686-unknown-kfreebsd-gnu
  fi

  ./configure --prefix=/usr --libdir=/usr/lib32 --host=$_HOST \
    --sysconfdir=/etc \
    --with-gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast,virgl \
    --with-egl-platforms=x11,drm,wayland \
    --enable-llvm-shared-libs \
    --enable-egl \
    --enable-gallium-llvm \
    --enable-opencl --enable-opencl-icd \
    --with-clang-libdir=/usr/lib32
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/$pkgbase-$pkgver

  install -vm755 -d $pkgdir/usr/lib32/
  cp -rv $srcdir/fakeinstall/usr/lib32/lib*OpenCL* $pkgdir/usr/lib32/
  cp -rv $srcdir/fakeinstall/usr/lib32/gallium-pipe $pkgdir/usr/lib32/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: