# U-Boot: UDOO
# Maintainer: André Silva <emulatorman@parabola.nu>

buildarch=4

pkgbase=uboot4extlinux-udoo
pkgname=('uboot4extlinux-udoo_dl' 'uboot4extlinux-udoo_quad')
pkgver=2015.01
pkgrel=3
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('bc')
backup=(boot/extlinux/extlinux.conf)
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        '0002-kernel-add-support-for-gcc-5.patch'
        'extlinux.conf')
md5sums=('7f08dc9e98a71652bd6968888ed6ec95'
         'f90125a266a2cd80980464f949d03d88'
         '721a46867e189d8dedc6b6f86a536a34'
         'b5112dc5343fea858091b9708db1f170')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
  patch -Np1 -i ../0002-kernel-add-support-for-gcc-5.patch
}

build() {
  cd u-boot-${pkgver}
  
  unset CFLAGS CXXFLAGS LDFLAGS
  
  mkdir bins
  for i in dl quad; do
    make distclean
    make udoo_${i}_config
    make
    mv u-boot.imx bins/u-boot-${i}.imx
  done
}

package_uboot4extlinux-udoo_dl() {
  pkgdesc="U-Boot with Extlinux support for UDOO Dual"
  conflicts=('uboot-udoo' 'uboot4extlinux-udoo' 'uboot4grub-udoo')
  provides=('uboot4extlinux-udoo')
  install=${pkgbase}.install

  mkdir -p "${pkgdir}"/boot/extlinux
  cp u-boot-${pkgver}/bins/u-boot-dl.imx "${pkgdir}"/boot/u-boot.imx
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}

package_uboot4extlinux-udoo_quad() {
  pkgdesc="U-Boot with Extlinux support for UDOO Quad"
  conflicts=('uboot-udoo' 'uboot4extlinux-udoo' 'uboot4grub-udoo')
  provides=('uboot4extlinux-udoo')
  install=${pkgbase}.install

  mkdir -p "${pkgdir}"/boot/extlinux
  cp u-boot-${pkgver}/bins/u-boot-quad.imx "${pkgdir}"/boot/u-boot.imx
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}