# Maintainer (arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor: mortzu <me@mortzu.de>
# Contributor: fnord0 <fnord0@riseup.net>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>


# parabola changes and rationale:
#  - no significant change - re-package for linux-libre
#  - pin to kernel versions


# build order:
#   acpi_call-dkms          <- acpi_call-lts
#                              acpi_call
#   linux-libre-lts-headers <- acpi_call-lts
#                              tp_smapi-lts
#   linux-libre-headers     <- acpi_call
#                              tp_smapi
#
# NOTE: It is normally not necessary to edit any of these PKGBUILDs.
# These packages may be built as a batch, with the helper script:
#   'scripts/package-all-acpi_call-tp_smapi'
# Simply edit 'KERNEL_VER' and/or 'KERNEL_LTS_VER' in the helper script.
# It will build any or all of the above packages,
# but only those for which the PKGBUILD '_basekernel' differs,
# update '_basekernel', and commit the changes to VCS, if successful.


_basekernel=6.7.4

pkgname=acpi_call-dkms
_tag='9f1c0b5d046bdfdec769809435257647fd475473' # git rev-parse v${_tag_name}
pkgver=1.2.2
pkgrel=1
pkgrel+=.parabola1.basekernel${_basekernel}
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call - module sources'
pkgdesc+=" (for 'linux-libre')"
url='https://github.com/nix-community/acpi_call'
arch=('any')
arch=('armv7h' 'i686' 'x86_64') # just to simplify the package-all-acpi_call-tp_smapi script
license=('GPL')
depends=('dkms')
makedepends=('git')
provides=("acpi_call=${pkgver}-${pkgrel%%.*}")
conflicts=('acpi_call')
source=("git+https://github.com/nix-community/acpi_call.git#tag=${_tag}"
        'dkms.conf')
b2sums=('SKIP'
        '504da1102e778fe54368e990408dbef02f5b2ce91f683d170f3d6a1a2f9349d00d61dcbddd0262a8dfc958ea0964135ba58d8dd88ac06bd10b5e13b90f11faef')

package() {
  install -D -m0644 acpi_call/{Makefile,acpi_call.c} dkms.conf -t "${pkgdir}"/usr/src/acpi_call-${pkgver}
  echo acpi_call | install -D -m0644 /dev/stdin "${pkgdir}"/usr/lib/modules-load.d/acpi_call.conf
  install -d -m0755 "${pkgdir}"/usr/share/acpi_call
  cp -dr --no-preserve=ownership acpi_call/{examples,support} "${pkgdir}"/usr/share/acpi_call/
}