# Maintainer (Arch): schuay <jakob.gruber@gmail.com>
# Contributor (Arch): Mike Sampson <mike at sambodata dot com>
# Contributor (Arch): Adrian Stratulat <adrian.stratulat at inboxcom>
# Contributor (Arch): Anton Bazhenov <anton.bazhenov at gmail>
# Contributor (Arch): KillaB <xGenoBlast@gmail.com>
# Contributor (Arch): Callan Barrett <wizzomafizzo@gmail.com>
# Contributor (Arch): Christian Schmidt <xmucknertx@googlemail.com>
# Contributor (Arch): Sebastian Sareyko <public@nooms.de>
# Contributor: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=angband
_pkgname=$pkgname-libre
pkgver=4.1.0
pkgrel=1.parabola1
pkgdesc="A roguelike dungeon exploration game based on the writings of JRR Tolkien, without nonfree artwork and sound effects"
arch=('i686' 'x86_64' 'armv7h')
url="http://rephial.org/"
license=('GPL2' 'custom')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('sdl_image' 'sdl_ttf' 'sdl_mixer' 'ncurses')
makedepends=('python-docutils')
mksource=("http://rephial.org/downloads/${pkgver:0:3}/${pkgname}-${pkgver}.tar.gz")
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz" 'libre.patch')

mksource() {
  cd "${srcdir}/${pkgname}-master"

  # remove nonfree stuff from source
  rm -v lib/sounds/*.mp3
  rm -v lib/tiles/shockbolt/64x64.png
}

prepare() {
  cd "${srcdir}/${pkgname}-master"

  # Fix detection of ncurses config script for ncurses 6.0
  sed -i 's/ncursesw5-config/ncursesw6-config/g' acinclude.m4

  # remove nonfree references
  patch -Np1 -i ../libre.patch
}

build() {
  cd "${srcdir}/${pkgname}-master"

  # ld fix for 4.1.0-1.parabola1
  sed -i 's/-Wl,-r/& -no-pie/' src/Makefile

  ./autogen.sh

  ./configure \
    --prefix=/usr \
    --bindir=/usr/bin \
    --sysconfdir=/usr/share/$pkgname \
    --with-configpath=/usr/share/$pkgname \
    --with-libpath=/usr/share/$pkgname \
    --enable-gtk \
    --enable-sdl \
    --enable-sdl-mixer

  make
}

package() {
  cd "${srcdir}/${pkgname}-master"

  make DESTDIR="${pkgdir}" install

  rm -f "${pkgdir}/usr/share/$pkgname/*/delete.me"
  install -Dm644 copying.txt "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

mksha256sums=('ea52266e52b66d6bf2ab3728b3bc6c7c3875130973430021e31bf56000c0df8b')
sha256sums=('07a50b78ff06acee720a0ca11597c69a133aeac6b479dcf2b0101e8402c4b522'
            'fa1524d1a3c5768b9090630d16393274fe007f87f3c0a00c4ffb5fc66e84fee9')