# $Id: PKGBUILD 188496 2013-06-15 04:38:11Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=arora
pkgname=arora-libre
pkgver=0.11.0
pkgrel=4
pkgdesc='Lightweight cross-platform Web browser, without nonfree flash recommendation and non-privacy search providers'
url='http://code.google.com/p/arora/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('qtwebkit' 'desktop-file-utils')
source=("http://${_pkgname}.googlecode.com/files/${_pkgname}-${pkgver}.tar.gz"
        'searchengines.qrc'
        'libre.patch'
        'duckduckgo-html.xml'
        'seeks-search.xml'
        'wikipedia-en.xml'
        'yacy.xml')
sha1sums=('480cfd7482cccbb7ece866fa10afe9acace29b31'
          'd64bdfe9022f8b4b0745a0d9cc1094ee80bbc897'
          '3982032d669077644d485f4d04d4ae4891bdb0e3'
          'e96f2d92b24daad0cfa28d02a003b92042651de0'
          '07bc208fbc3bf3d08192b2c07e550525953fc0b2'
          '3eea200350f7436bb2d744f8b6af1b5bbb758e51'
          '2d515947a8cbeea831490727e88c89ebee17c313')

install=install

prepare() {
        cd "${srcdir}/${_pkgname}-${pkgver}"
        # remove non-privacy search providers
        rm -r src/data/searchengines/*
        install -m644 $srcdir/searchengines.qrc src/data/searchengines
        install -m644 "$srcdir/"{duckduckgo-html,seeks-search,wikipedia-en,yacy}.xml src/data/searchengines    
        # remove nonfree flash recommendation
        patch -Np1 -i $srcdir/libre.patch
        sed -i '\|Flash|d' src/settings.cpp
}

build() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	qmake-qt4 PREFIX='/usr' 'CONFIG-=debug' -r
	make
}

package() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make INSTALL_ROOT="${pkgdir}" install
}