# $Id: PKGBUILD 195359 2016-11-11 13:54:46Z arojas $
# Maintainer (Arch): Laurent Carlier <lordheavym@gmail.com>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): mightyjaym <jmambrosino@gmail.com>
# Contributor (Arch): moostik <mooostik_at_gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=audex
pkgver=0.79+84+g25d4ca1
pkgrel=1.parabola1
pkgdesc="A CDDA extraction tool with a ftp upload function for KDE, without nonfree faac recommendation"
arch=('i686' 'x86_64' 'armv7h')
url="http://kde-apps.org/content/show.php?content=77125"
license=('GPL')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
depends=('libkcddb' 'hicolor-icon-theme' 'kcmutils')
makedepends=('extra-cmake-modules' 'git')
optdepends=('vorbis-tools: OGG encoder'
	'flac: FLAC encoder'
	'lame: MP3 encoder')
_commit=25d4ca113e27d2bce16fa4ef36f969fe5f129061 # master
source=("git://git.kde.org/audex.git#commit=$_commit")
md5sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed -e 's/-/+/g' -e 's/v//'
}

build() {
  cd ${pkgname}

  mkdir build
  cd build

  cmake ../  \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd ${pkgname}/build

  make DESTDIR=${pkgdir} install
}