# $Id: PKGBUILD 102570 2013-12-15 11:45:02Z tredaelli $
# Maintainer: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>

_pkgname=bfgminer
pkgname=bfgminer-libre
pkgver=3.8.1
pkgrel=1
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, without nonfree OpenCL recommendation."
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'jansson' 'libevent' 'libmicrohttpd' 'libusbx' 'lm_sensors')
makedepends=('uthash' 'yasm')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
url='https://bitcointalk.org/index.php?topic=168174.0'
license=('GPL3')
source=(http://luke.dashjr.org/programs/bitcoin/files/$_pkgname/$pkgver/$_pkgname-$pkgver.tbz2
        remove-dangerous-rpath.patch)
sha256sums=('73bf12cb978e0062f79463abb49f9d6a40c21f5db61e057c759dcca1dedc4e29'
            'd26d07ca23ae25798c4db37cfda1a6a76f22d06e73efab1ddf62b3e1a7eef04c')

prepare() {
  cd "$srcdir"/$_pkgname-$pkgver

  patch -p0 < "${srcdir}"/remove-dangerous-rpath.patch
  NOSUBMODULES=1 ./autogen.sh
}

build() {
  cd "$srcdir"/$_pkgname-$pkgver

  ./configure	--prefix=/usr \
	  	--enable-cpumining \
		--enable-bfsb \
		--enable-metabank \
  		--enable-scrypt \
		--enable-opencl
  # --enable-knc (FS#33640)
  make
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}