# $Id: PKGBUILD 200603 2013-11-29 19:17:58Z dreisner $

# Contributor: FUBAR <mrfubar@gmail.com>
# Contributor: simo <simo@archlinux.org>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=bitlbee
pkgname=bitlbee-libre
pkgver=3.2.1
pkgrel=1
pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC, without Skype support'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gnutls' 'glib2')
makedepends=('asciidoc' 'libotr3')
optdepends=('libotr3: for OTR encryption support'
            'xinetd: to run bitlbee through xinetd')
provides=$_pkgname=$pkgver
conflicts=$_pkgname
replaces=$_pkgname
source=("http://get.bitlbee.org/src/${_pkgname}-${pkgver}.tar.gz"
        'xinetd'
        'bitlbee.tmpfiles')
sha1sums=('954471ab87206826c072f31b3def40a1be5a78f5'
          '5e0af27ba9cc4fe455e3381c75fc49a9326e2f17'
          '3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
        'etc/bitlbee/motd.txt'
        'etc/xinetd.d/bitlbee')
install=bitlbee.install

build() {
  cd "$_pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --etcdir=/etc/bitlbee \
    --sbindir=/usr/bin \
    --pidfile=/run/bitlbee/bitlbee.pid \
    --ipcsocket=/run/bitlbee/bitlbee.sock \
    --systemdsystemunitdir=/usr/lib/systemd/system \
    --ssl=gnutls \
    --strip=0 \
    --otr=plugin \
    --skype=0

  # hacky: build against libotr3
  sed -i 's,^OTRFLAGS=.*,OTRFLAGS=-lotr3,' Makefile.settings
  sed -i 's,#include.*libotr,&3,' otr.h

  make
}

package() {
  make -C "$_pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev}

  install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
  install -Dm644 "$srcdir/xinetd" "$pkgdir/etc/xinetd.d/bitlbee"
  install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}