# $Id: PKGBUILD 100133 2013-11-01 20:20:45Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: durbatuluk <dvdscripter@gmail.org>
# Contributor: Steve Ponsford <sp4d@lavabit.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=blackbox
pkgname=${_pkgname}-libre
pkgver=0.70.1
pkgrel=11
pkgdesc="A window manager for X11, without nonfree programs on the menu"
url="http://blackboxwm.sourceforge.net/"
arch=('i686' 'x86_64')
depends=('gcc-libs' 'libxft' 'libxext' 'libx11' 'libxt')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
license=('MIT')
source=(http://downloads.sourceforge.net/blackboxwm/$_pkgname-$pkgver.tar.gz
	gcc4.3.patch
	bbdock.patch
	bsetbg-feh.patch
	textpropertytostring-unconditional.patch
        menu)
md5sums=('2d173b95ca5e64ef478c6a5d2deee9df'
         'bc7a1335d77cdeb6f85cba4d01e68e63'
         '69c5a5e981b087b2d8267cab996b48dd'
         'e7fb0d5bfd95820c0194ec73df66dadc'
         '3b92ad246f07126dd55ae9634d6e875e'
         'f4fefa5f25c65c5d9a601e9c14646757')

build() {
  cd $srcdir/$_pkgname-$pkgver

  patch -Np1 -i ../gcc4.3.patch
  patch -Np0 -i ../bbdock.patch
  patch -Np0 -i ../bsetbg-feh.patch
  patch -Np1 -i ../textpropertytostring-unconditional.patch

  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd $srcdir/$_pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -D -m644 LICENSE $pkgdir/usr/share/licenses/$_pkgname/LICENSE
  install -D -m644 $srcdir/menu $pkgdir/usr/share/$_pkgname/menu
}