# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Henry Jensen <hjensen@connochaetos.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>

pkgname=cdrkit-libre
pkgver=1.1.11
pkgrel=2
pkgdesc="Suite of programs for CD/DVD recording, ISO image creation, and audio CD extraction"
arch=('i686' 'x86_64')
url="http://cdrkit.org/"
license=('GPL2')
depends=('file' 'bzip2' 'perl')
makedepends=('cmake')
provides=('cdrtools' "cdrkit=${pkgver}")
conflicts=('cdrtools' 'cdrkit')
replaces=('cdrtools' 'cdrkit')
source=(http://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}.tar.gz)

mksource() {
    if [ ! -d ${pkgname}-${pkgver} ]; then
        wget -O - http://cdrkit.org/releases/${pkgname/-libre/}-${pkgver}.tar.gz | \
        bsdtar xzf -

        mv -v ${pkgname/-libre/}-${pkgver} ${pkgname}-${pkgver}
    fi

    rm -rvf ${pkgname}-${pkgver}/{doc/genisoimage/README.hfs_boot,genisoimage/apple_driver.{c,8}}

    tar czf ${pkgname}-${pkgver}.tar.gz ${pkgname}-${pkgver}/
    rm -r ${pkgname}-${pkgver}/
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX="$pkgdir/usr" install

  # Make symlinks for cdrtools compatibility
  cd "$pkgdir/usr/bin"
  ln -s wodim cdrecord
  ln -s readom readcd
  ln -s genisoimage mkisofs
  ln -s genisoimage mkhybrid
  ln -s icedax cdda2wav

  cd "$pkgdir/usr/share/man/man1"
  ln -s wodim.1 cdrecord.1
  ln -s readom.1 readcd.1
  ln -s genisoimage.1 mkisofs.1
  ln -s genisoimage.1 mkhybrid.1
  ln -s icedax.1 cdda2wav.1
}
md5sums=('e851c2d69ca17df7cfaabfa0d0e8e435')