# $Id: PKGBUILD 272647 2016-07-28 19:05:20Z heftig $
# Contributor (Arch): Dale Blount <dale@archlinux.org>
# Contributor (Arch): Gregor Ibic <gregor.ibic@intelicom.si>
# Maintainer (Arch): Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

_pkgname=clamav-libre
pkgname=clamav
pkgver=0.99.2
pkgrel=2.parabola1
pkgdesc='Anti-virus toolkit for Unix, without nonfree decompression engine for RAR archives'
url='http://www.clamav.net/'
license=('GPL')
arch=('i686' 'x86_64' 'armv7h')
makedepends=('libmilter')
makedepends_i686=('llvm35')
makedepends_x86_64=("${makedepends_i686[@]}")
depends=('bzip2' 'libltdl' 'libxml2' 'curl')
depends_i686=('llvm35-libs')
depends_x86_64=("${depends_i686[@]}")
depends_armv7h=('gcc-libs')
validpgpkeys=('B964E6D7BC7D7C82CCB8D45840B8EA2364221D53'
              'F79FB2D08751574C5D3FDFFBB3D5342C260429A0')
mksource=("http://www.clamav.net/downloads/production/${pkgname}-${pkgver}.tar.gz"{,.sig})
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        'logrotate'
        'tmpfiles.d'
        'clamd.conf'
        'freshclam.conf'
        'clamd.service'
        'freshclamd.service')
mksha1sums=('c1a47411834d8527f7b40727aebee63f01d488af'
            'SKIP')
sha1sums=('f6460a9ce0edb7d76397e4f9b1ebd3cc2c7d544c'
          'bb488a56b0f6a0760446cde89c1e3321e2717b78'
          'a224ea9b4d0f4f196827347d54bed51e11c197ea'
          '887f624eb305f2446f55d8339e2972ad0cfe2b79'
          'b767837d0279ad30b92c314cb762b73e5ad0415e'
          '77899cce83f04cbe134b30da376f879d2841f769'
          'cda9a087e5593992150cb456e34c5f6f589aca82')

backup=('etc/clamav/clamd.conf'
        'etc/clamav/freshclam.conf'
        'etc/logrotate.d/clamav')

install=install

mksource() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	msg2 "remove nonfree unRAR utility files from the source"
	rm -rv libclamunrar
	rm -v COPYING.unrar
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	if [ "$CARCH" != "armv7h" ]; then
		local extra_options="--with-system-llvm \
			             --with-llvm-linking=dynamic"
	fi
	./configure \
		--prefix=/usr \
		--sbindir=/usr/bin \
		--sysconfdir=/etc/clamav \
		--with-dbdir=/var/lib/clamav \
		--disable-clamav \
		--enable-milter \
		--disable-unrar \
		$extra_options
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install

	install -Dm644 ../clamd.conf "${pkgdir}"/etc/clamav/clamd.conf
	install -Dm644 ../freshclam.conf "${pkgdir}"/etc/clamav/freshclam.conf
	install -Dm644 ../freshclamd.service "${pkgdir}"/usr/lib/systemd/system/freshclamd.service
	install -Dm644 ../clamd.service "${pkgdir}"/usr/lib/systemd/system/clamd.service
	install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/clamav.conf
	install -Dm644 ../logrotate "${pkgdir}"/etc/logrotate.d/clamav

	install -d -o 64 -g 64 "${pkgdir}"/var/log/clamav
	install -d -o 64 -g 64 "${pkgdir}"/var/lib/clamav
}