# $Id: PKGBUILD 194740 2016-11-06 18:16:50Z arojas $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Stéphane Gaudreault <stephane@archlinux.org>
# Contributor (Arch): BlackEagle <ike.devolder@gmail.com>
# Contributor (Arch): Dany Martineau <dany.luc.martineau@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Kete <kete@ninthfloor.org>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=clementine
_pkgname=$pkgname-libre
pkgver=1.3.1
pkgrel=4.parabola1
pkgdesc='A modern music player and library organizer, without nonfree artwork and Spotify support'
url="http://www.$pkgname-player.org/"
license=('GPL')
arch=('i686' 'x86_64' 'armv7h')
replaces=("$_pkgname")
conflicts=("$_pkgname")
depends=('chromaprint' 'crypto++' 'fftw' 'gcc-libs' 'glew' 'glib2' 'glibc'
         'gst-plugins-base-libs' 'gstreamer' 'libcdio' 'libechonest' 'libgl'
         'libgpod' 'liblastfm' 'libmtp' 'libpulse' 'libx11' 'protobuf' 'qjson'
         'qt4' 'sqlite' 'taglib' 'zlib')
makedepends=('boost' 'cmake' 'mesa' 'sparsehash')
optdepends=('gst-plugins-base: "Base" plugin libraries'
            'gst-plugins-good: "Good" plugin libraries'
            'gst-plugins-bad: "Bad" plugin libraries'
            'gst-plugins-ugly: "Ugly" plugin libraries'
            'gst-libav: Libav plugin'
            'gvfs: Various devices support')
mksource=("${pkgname}-${pkgver}.tar.gz::https://github.com/$pkgname-player/${pkgname^}/archive/${pkgver}.tar.gz")
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        clementine-gcc6.patch::"https://github.com/clementine-player/Clementine/commit/e31278.patch"
        remove-nonfree-artwork-and-spotify.patch
        moognu.png)
mksha256sums=('f885931a9ab7c88607d07b50c64fcce46fc05f13dd2c0a04188c94eff938f37c')
sha256sums=('9b84b3b867963da265308b150746aec0faaf5bcd79f78e3363a741edda7286ec'
            '785c485d0a2398a31728a012f6869573f6714359c0d65fbc06f7532c86b82643'
            'aecd13727a55a4556b70db73519a6ff4cecabefadedad9f952b5499aa5131711'
            'c6918617769152f3617c61f721819e69d03f671b85760b11cfe45abd53955bc4')

mksource() {
  cd ${pkgname^}-${pkgver}

  # remove nonfree artwork for the Nyan Cat plugin
  # https://labs.parabola.nu/issues/329
  rm -v data/nyancat.png
}

prepare() {
  cd ${pkgname^}-${pkgver}

  # remove nonfree artwork and Spotify references
  patch -Np1 -i ../remove-nonfree-artwork-and-spotify.patch

  # remove Spotifyblob files
  rm -rv ext/{$pkgname-spotifyblob,lib${pkgname}-spotifyblob}

  # remove Spotify files
  rm -rv src/internet/spotify
  rm -v data/icons/svg/spotify.svg
  rm -v data/providers/{22x22,32x32,48x48}/spotify.png
  rm -v data/spotify-attribution.png
  rm -v data/clementine-spotify-public.pem
  rm -v cmake/SpotifyVersion.cmake
  rm -v data/schema/schema-30.sql
  rm -v src/globalsearch/spotifysearchprovider.{cpp,h}

  # move free Nyan Cat replacement mascot (MooGNU) to the source code
  # https://labs.parabola.nu/issues/329
  install -m644 -v ../moognu.png data

  # create a blank file because it's a dependency for Clementine
  touch data/schema/schema-30.sql

  # fix build with GCC 6
  patch -p1 -i ../clementine-gcc6.patch

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build
}

build() {
  cd ${pkgname^}-${pkgver}/build

  cmake .. \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr'
  make
}

package() {
  cd ${pkgname^}-${pkgver}/build

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: