# $Id: PKGBUILD 189264 2016-09-13 14:55:02Z felixonmars $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=debootstrap
pkgver=1.0.83
pkgrel=1.parabola1
pkgdesc="Bootstrap a basic gNewSense and Trisquel system, without Debian support"
arch=('any')
license=('GPL')
url="https://tracker.debian.org/pkg/debootstrap"
depends=('wget' 'binutils')
makedepends=('git' 'makedev')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("git+https://anonscm.debian.org/git/d-i/debootstrap.git#tag=$pkgver"
        arch-detect.patch
        debootstrap.8
        gnewsense
        trisquel)
optdepends=('gnupg: check release signatures')
md5sums=('SKIP'
         '60043aaeb9afc1c2d7d2a2d9888eca35'
         '654761198068b51b027d47cba4b7cfa2'
         '13978bdd1d877a0dd2c3c874ecd54f03'
         'b020aa8426e70a6024c8e76312c17d78')

prepare() {
  cd debootstrap

  sed -i 's/sbin/bin/g' Makefile

  # gNewSense/Trisquel defaults
  sed -i 's|export PATH|export PATH="/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin"|' debootstrap

  # Detect Architecture
  patch -p1 -i ../arch-detect.patch

  # Workaround permission errors
  # MAKEDEV is not happy with the instructions here
  sed -e 's/install -o root -g root/install/' \
      -e '/chown 0:0 dev/d' \
      -e 's/(cd dev && $(MAKEDEV) std ptmx fd consoleonly)/$(MAKEDEV) -d dev std ptmx fd consoleonly/' \
      -i Makefile

  # Remove Debian files
  rm -v debootstrap.8

  # Add rebranded man
  install -m644 ../debootstrap.8 .

  # Remove Debian scripts
  rm -v scripts/*

  # Add gNewSense script
  install -m644 $srcdir/gnewsense scripts

  # Add Trisquel script
  install -m644 $srcdir/trisquel scripts

  # Enter to scripts dir
  cd scripts

  # Create gNewSense symlinks
  ln -s gnewsense parkes

  # Create Trisquel symlinks
  ln -s trisquel awen
  ln -s trisquel belenos
  ln -s trisquel brigantia
  ln -s trisquel dagda
  ln -s trisquel dwyn
  ln -s trisquel robur
  ln -s trisquel slaine
  ln -s trisquel taranis
  ln -s trisquel toutatis
}

build() {
  cd debootstrap
  fakeroot make
}

package() {
  cd debootstrap
  make DESTDIR="$pkgdir" install

  install -Dm644 debootstrap.8 "$pkgdir"/usr/share/man/man8/debootstrap.8
}