# $Id$
# Maintainer: Dan McGee <dan@archlinux.org>
# Contributor: Shahar Weiss <sweiss4@gmx.net>

pkgname=django
pkgver=1.3.1
pkgrel=2
pkgdesc="A high-level Python Web framework."
arch=('any')
license=('BSD')
url="http://www.djangoproject.com/"
depends=('python2')
makedepends=('python2-distribute')
optdepends=('mysql-python: for MySQL backend'
            'python2-psycopg2: for PostgreSQL backend')
source=("https://www.djangoproject.com/m/releases/1.3/Django-$pkgver.tar.gz"
        diff-django_branches_releases_1.3.X-from-16768-to-17460.diff)
md5sums=('62d8642fd06b9a0bf8544178f8500767'
         'd09d8f9e156b9aa1b580a1b43209b99f')
sha256sums=('af9118c4e8a063deb0b8cda901fcff2b805e7cf496c93fd43507163f3cde156b'
            '8e08b5b5bbe7c042a1df4d5615a9d068ec6718fd00bef627c0a9a9e48ee58c15')

build() {
  cd "$srcdir/Django-$pkgver"
  patch -Np1 -i ../diff-django_branches_releases_1.3.X-from-16768-to-17460.diff
  python2 setup.py build
}

package() {
  cd "$srcdir/Django-$pkgver"
  python2 setup.py install --root="$pkgdir" --optimize=1

  install -Dm644 extras/django_bash_completion \
    "$pkgdir"/etc/bash_completion.d/django

  find "$pkgdir"/usr/lib/python2.7/site-packages/django/ -name '*.py' | \
    xargs sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|"

  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

_pkgname=$pkgname
pkgname=django13
pkgdesc+=" (legacy version for ParabolaWeb)"
pkgrel+=.1
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")