# $Id: PKGBUILD 174204 2016-05-07 17:01:08Z arojas $
# Maintainer (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Fredrik Hammar <Horney_C86@Hotmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=dvdrip
pkgver=0.98.11
pkgrel=12.parabola1
pkgdesc="A Gtk frontend for transcode writen in Perl, without opcional hal and nonfree rar vobsub compression support"
arch=('i686' 'x86_64' 'armv7h')
license=('custom')
url="http://www.exit1.org/${pkgname}/"
depends=('perl-gtk2-ex-formfactory' 'transcode' 'imagemagick'
         'perl-libintl-perl' 'desktop-file-utils' 'perl-event-execflow')
optdepends=('ogmtools: for ogm/odd video creation'
            'lsdvd: fast reading of DVD table'
            'fping: for cluster support')
source=("http://www.exit1.org/${pkgname}/dist/${pkgname}-${pkgver}.tar.gz"
        "${pkgname}.desktop" "libre.patch")
options=('!emptydirs' '!makeflags')
replaces=("${pkgname}-libre")
conflicts=("${pkgname}-libre")
md5sums=('6dfa4199d451757a37eea233a07da4c0'
         'e91cf411928fd0500d07a0022b4ef546'
         'bc006d3b3447f8b62ae6ba29773a064b')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # install module in vendor directories.
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make install DESTDIR="${pkgdir}"

  # remove perllocal.pod and .packlist
  find ${pkgdir} -name perllocal.pod -delete
  find ${pkgdir} -name .packlist -delete

  install -Dm644 ${srcdir}/${pkgname}.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm 644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}