# $Id: PKGBUILD 113887 2014-07-01 08:03:15Z fyan $
# Maintainer (Arch): Alexander Baldeck <alexander@archlinux.org>
# Contributor (Arch): dorphell <dorphell@archlinux.org>
# Contributor (Arch): Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=dvdrtools
_pkgname=$pkgname-libre
pkgver=0.3.1
pkgrel=4.parabola1.1
pkgdesc="A fork of cdrtools, with the primary goal of supporting writable DVD drives, without nonfree apple_driver utility"
arch=('i686' 'x86_64' 'armv7h')
url="http://savannah.nongnu.org/projects/$pkgname/"
license=('GPL2')
depends=('file' 'bash')
makedepends=('transcode')
optdepends=('transcode: video/DVD ripper and encoder for the terminal/console')
conflicts=("$_pkgname" 'cdrkit')
replaces=("$_pkgname")
mksource=(ftp://ftp.archlinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz)
source=(https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver.tar.gz)
mkmd5sums=('5707b7e877b853e258cd738938833006')
md5sums=('2f5328b875b34b48f27b5ec4c26b35a6')

mksource() {
  cd "$srcdir/$pkgname-$pkgver"

  # Remove nonfree apple_driver utility
  rm -rvf {mkisofs/README.hfs_boot,apple_driver{.8,.c,.mk,_man.mk}}
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # Make symlinks for cdrtools compatibility
  ln -s dvdrecord $pkgdir/usr/bin/cdrecord
  ln -s dvdrecord $pkgdir/usr/bin/wodim
  ln -s mkisofs   $pkgdir/usr/bin/genisoimage
  ln -s mkisofs   $pkgdir/usr/bin/mkhybrid
  ln -s readcd    $pkgdir/usr/bin/readom

  ln -s dvdrecord.1.gz $pkgdir/usr/share/man/man1/cdrecord.1.gz
  ln -s dvdrecord.1.gz $pkgdir/usr/share/man/man1/wodim.1.gz
  ln -s mkisofs.8.gz   $pkgdir/usr/share/man/man8/genisoimage.8.gz
  ln -s mkisofs.8.gz   $pkgdir/usr/share/man/man8/mkhybrid.8.gz
  ln -s readcd.1.gz    $pkgdir/usr/share/man/man1/readom.1.gz
}