# $Id: PKGBUILD 280227 2016-11-08 07:39:06Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>

pkgname=file-roller
pkgver=3.22.2
pkgrel=1.parabola1
pkgdesc="Create and modify archives, without nonfree unace and unrar recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(i686 x86_64 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(intltool itstool docbook-xsl gnome-common git)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
            'lrzip: lrzip archive support')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
groups=(gnome-extra)
options=(!emptydirs)
_commit=764cf9e2e29cdd047315de0fef1ed9798e0a6f45  # tags/3.22.2^0
source=("git://git.gnome.org/file-roller#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib/$pkgname --disable-static --disable-schemas-compile

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}