# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): Stefan Husmann <stefan-husmann@t-online.de>
# Contributor (Arch): Simon Lipp <sloonz+aur@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=fop
pkgver=2.1
pkgrel=1.parabola1
pkgdesc='XSL-FO implementation in Java.'
arch=('any')
url='http://xmlgraphics.apache.org/fop/'
license=('APACHE')
depends=('java-xmlgraphics-commons' 'java-commons-logging' 'java-commons-io' 'java-batik'
         'java-avalon-framework' 'java-qdox' 'fontbox' 'tomcat8' 'openicc')
makedepends=('apache-ant' 'jh')
source=("http://ftp-stud.hs-esslingen.de/pub/Mirrors/ftp.apache.org/dist/xmlgraphics/$pkgname/source/$pkgname-$pkgver-src.tar.gz"
        "https://repo.maven.apache.org/maven2/org/apache/xmlgraphics/${pkgname}/${pkgver}/${pkgname}-${pkgver}.pom"
        'fop.conf'
        'fop-fix_build.patch'
        'fop-replace_sRGB_profile.patch')
md5sums=('13b5b497dfb0ba8a01093dfc1a89d106'
         '38ec8e97c4dc787e99dcbba94b0e17d2'
         '3dc3325bf77afc787024f33e7d6ab99e'
         '5b720bb6f3c29673ae30679a19a41a4b'
         '7a5224d08d29ff343ffd7c889156fef9')
backup=('etc/fop.conf')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  rm -rv lib/*
  rm -v "src/java/org/apache/fop/pdf/sRGB Color Space Profile.icm"{,.LICENSE.txt}
  mkdir -p lib/build

  patch -Np1 -i "${srcdir}/fop-fix_build.patch"
  patch -Np1 -i "${srcdir}/fop-replace_sRGB_profile.patch"
  ln -sf /usr/share/java/qdox.jar lib/build/qdox.jar
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ant package javadocs \
    -lib /usr/share/java/serializer.jar \
    -lib /usr/share/java/xmlgraphics-commons.jar \
    -lib /usr/share/java/avalon-framework-api.jar \
    -lib /usr/share/java/avalon-framework-impl.jar \
    -lib /usr/share/java/commons-io.jar \
    -lib /usr/share/java/batik/batik-all.jar \
    -lib /usr/share/java/batik/batik-libs.jar \
    -lib /usr/share/java/tomcat8/servlet-api.jar \
    -lib /usr/share/java/xml-apis-ext.jar \
    -lib /usr/share/java/fontbox.jar
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  # Install license file
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"

  # Install documentation
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r "build/javadocs" "${pkgdir}/usr/share/doc/${pkgname}"

  # Install Maven artifacts
  export DESTDIR=${pkgdir}
  jh mvn-install "org.apache.xmlgraphics" ${pkgname} ${pkgver} \
    "${srcdir}/${pkgname}-${pkgver}.pom" \
    "build/${pkgname}.jar" \
    "${pkgname}-${pkgver}.jar"
  ln -s "/usr/share/java/${pkgname}-${pkgver}.jar" \
    "${pkgdir}/usr/share/java/${pkgname}.jar"

  install -d "${pkgdir}/usr/share/java/${pkgname}"
  ln -s "/usr/share/java/${pkgname}.jar" \
    "${pkgdir}/usr/share/java/${pkgname}/${pkgname}.jar"

  install -Dm0644 "../fop.conf" "$pkgdir/etc/fop.conf"
  install -Dm0755 "$pkgname" "$pkgdir/usr/bin/$pkgname"
}