# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor : Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Daniel Milewski <niitotantei@gmail.com>
# Contributor : André Silva <emulatorman@hyperbola.info>

pkgname=gnome-boxes
pkgver=3.30.3
pkgrel=1
pkgrel+=.par1
pkgdesc="Simple GNOME application to access remote or virtual systems"
pkgdesc+=", without suggestions (and logos) of nonfree operating systems"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://wiki.gnome.org/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
groups=('gnome')
depends=('cdrtools' 'gtk-vnc' 'libarchive' 'libgovirt' 'libgudev' 'libosinfo' 'libsecret'
         'libvirt-glib' 'mtools' 'qemu' 'spice-gtk3' 'tracker' 'webkit2gtk' 'freerdp')
makedepends=('git' 'gobject-introspection' 'itstool' 'meson' 'spice-protocol' 'vala')
_commit=d9253b816c8bd3df3de23e9e3ec0df187f27eb27  # tags/v3.30.3^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-boxes.git#commit=$_commit"
        "git+https://gitlab.gnome.org/GNOME/gtk-frdp.git"
        "git+https://gitlab.gnome.org/felipeborges/libovf-glib.git")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^v//;s/-/+/g'
}

prepare() {
  cd $pkgname
  git submodule init
  git config --local submodule.subprojects/gtk-frdp.url "$srcdir/gtk-frdp"
  git config --local submodule.subprojects/libovf-glib.url "$srcdir/libovf-glib"
  git submodule update

  # remove distro logos
  find ./data/osinfo/ -type f -name '*.xml' -exec sed -i '/<os /,/\/os>/ d' {} +
  # I'd rather not use Windows as example in user docs
  find ./help/ -type f \( -name '*.po' -o -name '*.page' \) -exec \
       sed -Ei 's/(Microsoft )?Windows(™)?/Parabola/' {} +
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}