# Parabola maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Parabola contributor: André Silva <andre.paulista@adinet.com.uy>
# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Sebastian Sareyko <public@nooms.de>

_pkgname=gnustep-base
pkgname=gnustep-base-libre
pkgver=1.24.0
pkgrel=2
pkgdesc="The GNUstep base package with exceptions enabled"
arch=('i686' 'x86_64')
url="http://www.gnustep.org/"
license=("GPL" "LGPL")
depends=(libxslt avahi gmp gcc-libs openssl libffi gnustep-make-libre gnutls)
makedepends=(gcc-objc)
conflicts=('gnustep-base-svn' 'gnustep-base')
provides=('gnustep-base')
groups=('gnustep-core')
options=('!emptydirs' '!makeflags')
source=(ftp://ftp.gnustep.org/pub/gnustep/core/$_pkgname-$pkgver.tar.gz)
md5sums=('53cd117e9f64729870e906b66d2314ba')

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  source /etc/profile.d/GNUstep.sh
  ./configure --prefix=/usr --sysconfdir=/etc/GNUstep \
	--with-ffi-include=/usr/lib/libffi-`pacman -Q libffi | cut -f2 -d\ |cut -f1 -d-`/include/
  # fix file ownership
  sed -i 's/tar -xf $(TIMEZONE_ARCHIVE);/tar -xf $(TIMEZONE_ARCHIVE);chown -R root:root * ;/' NSTimeZones/Makefile.postamble
  sed -i 's|.*gnutls_transport_set_lowat.*||' Source/GSSocketStream.m
  make VERBOSE=1
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  chown -R root.root "$pkgdir/"
}