# $Id: PKGBUILD 279663 2016-11-01 20:55:33Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=gst-plugins-bad
pkgver=1.10.0
pkgrel=1.parabola1
pkgdesc="GStreamer Multimedia Framework Bad Plugins, without nonfree faac support"
url="https://gstreamer.freedesktop.org/"
arch=(i686 x86_64 armv7h)
license=(LGPL)
depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls glu sbc rtmpdump
         libgudev graphene)
makedepends=(schroedinger libexif libdvdread libvdpau libmpeg2 python valgrind wildmidi librsvg
             gobject-introspection gtk-doc gtk3 clutter libtiger ladspa openal libusb
             qt5-declarative qt5-x11extras qt5-wayland vulkan-headers vulkan-icd-loader zbar
             autoconf-archive git libfdk-aac soundtouch spandsp fluidsynth neon)
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
options=(!emptydirs)
_commit=f2df164f88faa7798e0ce94e0530ff84a4c29f3d  # tags/1.10.0^0
source=("git://anongit.freedesktop.org/gstreamer/gst-plugins-bad#commit=$_commit"
        "gst-common::git://anongit.freedesktop.org/gstreamer/common")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.common.url "$srcdir/gst-common"
  git submodule update

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  # disable GL and GLX on armv7h
  [[ "$CARCH" = "armv7h" ]] && extra="--disable-gl --disable-glx --enable-gles2"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
    --with-package-name="GStreamer Bad Plugins (Parabola GNU/Linux-libre)" \
    --with-package-origin="https://www.parabola.nu/" \
    --with-gtk=3.0 \
    --enable-experimental --enable-gtk-doc --disable-static $extra

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname
  # don't have a camera for the camerabin test
  make -k check || :
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}