# $Id: PKGBUILD 200583 2013-11-29 11:48:46Z tpowa $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Keshav P R <(the.ridikulus.rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
# Contributor:  Mantas Mikulėnas <grawity@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

pkgname="gummiboot"
pkgver="39"
pkgrel="1"
pkgdesc="Simple text-mode UEFI Boot Manager (Parabola rebranded)"
url="http://freedesktop.org/wiki/Software/gummiboot"
arch=('x86_64' 'i686' 'mips64el')
license=('LGPL2.1')
makedepends=('gnu-efi-libs' 'docbook-xsl' 'git')
depends=('util-linux')
conflicts=('gummiboot-efi')
provides=('gummiboot-efi')
replaces=('gummiboot-efi')
options=('!strip' '!makeflags')
source=("git://anongit.freedesktop.org/${pkgname}#tag=${pkgver}"
        'loader.conf'
        'parabola.conf')
install="gummiboot.install"

build() {
	cd ${srcdir}/${pkgname}

	./autogen.sh
	./configure --sysconfdir=/etc  --with-efi-ldsdir=/usr/lib --libexecdir=/usr/lib --libdir=/usr/lib
	
	make
}

package() {
	## Install gummiboot example configuration files (can go away with systemd's kernel-install)
	install -D -m0644 "${srcdir}/loader.conf" "${pkgdir}/usr/lib/gummiboot/loader/loader.conf"
	install -D -m0644 "${srcdir}/parabola.conf" "${pkgdir}/usr/lib/gummiboot/loader/entries/parabola.conf"

	cd ${srcdir}/${pkgname}

	make DESTDIR="${pkgdir}" install
}
md5sums=('SKIP'
         '3d700d13aec5ab1b78a921eaf22e5bfa'
         '36ee74767ac8734dede1cbd0f4f275d7')