# $Id: PKGBUILD 115005 2014-07-05 03:31:29Z eric $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=hardinfo
pkgver=0.5.1
pkgrel=6.parabola1
pkgdesc="A system information and benchmark tool (Parabola rebranded)"
arch=('i686' 'x86_64' 'armv7h')
url="http://sourceforge.net/projects/hardinfo.berlios/"
license=('GPL2')
depends=('gtk2' 'libsoup')
options=('!emptydirs')
replaces=(${pkgname}-parabola)
conflicts=(${pkgname}-parabola)
source=(http://sourceforge.net/projects/hardinfo.berlios/files/${pkgname}-${pkgver}.tar.bz2
        fixsensors.patch hardinfo.distro
        hardinfo-gnu89_inline.patch)
sha1sums=('983f0445aa60e02156bc5a5eaedeffb30b8e4d64'
          'd2151dce76dca238102937d0e15541f172bca530'
          '9425e09191cd3a365a3afce57ca1973a6439fa57'
          '861a60aa2bdc56f95f496383b80399167cfdf995')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -p1 -i "${srcdir}/fixsensors.patch"
  patch -Np1 -i "${srcdir}/hardinfo-gnu89_inline.patch"
  sed -i 's|/usr/lib64|/usr/lib|' configure
  sed -i 's|lib64|lib|' binreloc.c
  sed -i 's|{ DB_PREFIX "debian_version",	"deb"  },|{ DB_PREFIX "hardinfo.distro",       "parabola"  },{ DB_PREFIX "debian_version",	"deb"  },|' computer.h 
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -D -m644 "${srcdir}/hardinfo.distro" "${pkgdir}/etc/hardinfo.distro"
}