# $Id: PKGBUILD 194002 2016-10-30 14:32:22Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=hexchat
pkgver=2.12.3
pkgrel=1.parabola1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference'
arch=('i686' 'x86_64' 'armv7h')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'gdk-pixbuf2' 'glib2' 'glibc' 'gtk2'
         'libcanberra' 'libnotify' 'libproxy' 'openssl' 'pango' 'pciutils')
makedepends=('intltool' 'iso-codes' 'lua' 'perl' 'python')
optdepends=('enchant: Spell check'
            'iso-codes: Display language names instead of codes'
            'lua: Lua plugin'
            'perl: Perl plugin'
            'python: Python plugin')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("http://dl.hexchat.net/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha256sums=('6f2b22372c7a9ed8ffab817079638e8f4178f5f8ba63c89cb3baa01be614f2ba'
            'SKIP')
validpgpkeys=('108BF2212A051F4A72B18448B3C7CE210DE76DFC') # Patrick Griffis

prepare() {
  cd ${pkgname}-${pkgver}

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -new-window %s\\n\\n";|iceweasel -new-window %s\\n\\n"\\\n		"NAME Open Link in a new Icecat Window\\n"		"CMD !icecat -new-window %s\\n\\n";|' src/common/hexchat.c
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix='/usr' \
    --enable-python='python3' \
    --enable-textfe
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: