# $Id$
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): tobias <tobias@archlinux.org>
# Contributor (Arch): K. Piche <kpiche@rogers.com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale:
#  - removed drumkits recommendation
#  - added contributors from .contrib to PKGBUILD

pkgname=hydrogen
pkgver=0.9.6.1
pkgrel=4.parabola3
pkgdesc="An advanced drum machine, without nonfree drumkits recommendation"
arch=('x86_64' 'i686' 'armv7h')
license=('GPL')
url="http://www.hydrogen-music.org/"
depends=('libarchive' 'liblrdf' 'qt4' 'jack' 'libpulse')
optdepends=('rubberband')
makedepends=('cmake')
source=("https://github.com/hydrogen-music/hydrogen/archive/$pkgver.tar.gz")
md5sums=('527a44eec22fd31f55e6b3cf1089613d')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  # Change to list with free licensed drumkits only
  sed -i -e 's|www[.]hydrogen-music[.]org/feeds/drumkit_list[.]php|repo.parabola.nu/other/hydrogen-libre/feeds/drumkit_list.php|'\
  $(grep -rlI 'www[.]hydrogen-music[.]org/feeds/drumkit_list[.]php')
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # lash will have to wait until I bring it into [extra] --schiv
  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
          -DWANT_CPPUNIT=OFF \
          -DWANT_LRDF=ON
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  # TODO: tell upstream to comply with freedesktop.org icon conventions
  sed -i 's:Icon=h2-icon:Icon=/usr/share/hydrogen/data/img/gray/h2-icon.svg:' \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
}

# vim:set ts=2 sw=2 et: