# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

_pkgbase=iceape
pkgbase=$_pkgbase-l10n

epoch=1
pkgver=2.49.2
pkgrel=1
arch=(any)

pkgdesc="Language pack for ${_pkgbase^}."
url="https://wiki.parabola.nu/$_pkgbase"
license=(MPL GPL)

depends=("$_pkgbase=$epoch:$pkgver")
makedepends=(unzip zip)

_languages=(
  'cs     "Czech"'
  'de     "German"'
  'en-GB  "English (British)"'
  'en-US  "English (American)"'
  'es-AR  "Spanish (Argentina)"'
  'es-ES  "Spanish (Spain)"'
  'fr     "French"'
  'hu     "Hungarian"'
  'it     "Italian"'
  'ja     "Japanese"'
  'lt     "Lithuanian"'
  'nb-NO  "Norwegian"'
  'nl     "Dutch"'
  'pl     "Polish"'
  'pt-PT  "Portuguese (Portugal)"'
  'ru     "Russian"'
  'sk     "Slovak"'
  'sv-SE  "Swedish"'
  'zh-CN  "Chinese (Simplified)"'
  'zh-TW  "Chinese (Traditional)"'
)

pkgname=()
source=('brand.dtd' 'brand.properties' 'communicator-region.properties' 'editor-region.properties' 'messenger-region.properties' 'navigator-region.properties')
_url=https://ftp.mozilla.org/pub/seamonkey/releases/$pkgver/langpack

for _lang in "${_languages[@]}"; do
  _locale=${_lang%% *}
  _pkgname=$pkgbase-${_locale,,}

  pkgname+=($_pkgname)
  source+=("$pkgbase-$pkgver-$_locale.xpi::$_url/seamonkey-$pkgver.$_locale.langpack.xpi")
  eval "package_$_pkgname() {
    _package $_lang
  }"
done

# Don't extract anything
noextract=(${source[@]%%::*})

_package() {
  pkgdesc="$2 language pack for Debian Iceape."
  replaces=(iceape-i18n-${1,,})
  conflicts=(iceape-i18n-${1,,})
  provides=(iceape-i18n-${1,,})

  unzip iceape-l10n-$pkgver-$1.xpi -d $1
  rm -v iceape-l10n-$pkgver-$1.xpi
  install -vDm644 $srcdir/brand.dtd $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/brand.properties $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/navigator-region.properties $1/chrome/$1/locale/$1/navigator-region/region.properties
  install -vDm644 $srcdir/messenger-region.properties $1/chrome/$1/locale/$1/messenger-region/region.properties
  install -vDm644 $srcdir/communicator-region.properties $1/chrome/$1/locale/$1/communicator-region/region.properties
  install -vDm644 $srcdir/editor-region.properties $1/chrome/$1/locale/$1/editor-region/region.properties
  sed -i -e 's/seamonkey/iceape/' $1/install.rdf
  rm -rv $1/chrome/$1/locale/$1/global-platform/{mac,win}

  cd $1
  zip -r langpack-$1@iceape.mozilla.org.xpi .
  mv -v langpack-$1@iceape.mozilla.org.xpi $srcdir
  cd ..
  rm -rv $1

  install -vDm644 langpack-$1@iceape.mozilla.org.xpi \
    "$pkgdir/usr/lib/iceape-$pkgver/extensions/langpack-$1@iceape.mozilla.org.xpi"
}

sha256sums=('21473f12638f447e573ce26d02297f9d966f61e04c5fcbb7fc30919a26a6c94b'
            'c01f71da0ed60a9a1e31325ca79ad3bf629496d42adb1871de756faa658db420'
            'd49655d6c7e6bbc16158d77a075f54b15b5740a6fe0cf9c6ea08df72ca44bcad'
            '41d8ae62c7af6b5e7168ba26a0b32e34e41a0357ed6e83a2097307c9b2e10afc'
            'dc8c43b153d063e099a50399b07069c4e00550f2826ad59d0eb14f6247801c03'
            '2118452fa650182eae694100711634021b7b1b574e285bd2f94902a9aa8533c2'
            'f3d1fcc5e55887652bfeb92720f2ff5c4f5795ff0b5c5cf2b99d2306cf785bf2'
            '3b0ca0d924130ffec2090e4576e95041a317085be8333042243198d0c22227ce'
            '2831d0bf9ca092090239bc5822ad4bad68ef94ffbd7427cca9c8fd073ae03a30'
            '9102d7a3d14c00d3d694c063e9c2087e5e75a3f8810689df14625dfbcc4caa22'
            'dad877f67d5eb03f9da57fc0f4d6cda5b8429784c7f57f4b18d05e543f87a7cd'
            '82e76f9e97ee7685edc45f7425723280555591da02df207f572e57876588ece3'
            'fd7a23a23d331e0d97a7d48408388771a4443911d54c0e70958d67606efabd05'
            '75102b128e373e803bbb531d1cf765b12ffd1cd21e161a257aeebcdb5f40bf25'
            'a41ab25f3336b4d236b7bc4e0c252141e165de7a122299cb6547f08b5b804da5'
            '3489b511763104efa6ac5cabf11206bf2aceb5bbdce4122efa7c9e0f2765fb44'
            '8443d56226e2c8483c57acb890c337acd7afcbd1fbce87c441a690dd4ec5c940'
            'afdd49dffc9296bb654b3868ed96a601ae9aaa015357706c162ecf59b35b3b6f'
            '18052040a814f3af64cbc80f8976729f4fef68d605abf921a17accebc8e1d7e5'
            '2a972ae25bd7a5d2ffcb191425bb3fc7b527f4069b9c426fea9c473563125fca'
            '23b3c609a7b3a91de05b4d0dabcbf9505d30ac9eb3cc326f04b928c71df5247d'
            '31800aa4cf83f3f99ed86e85230fe979b4dc6b650240f497f6e27c3a8e692074'
            '486b0b3e379b83d949167aadc5a489c6f0ea8e33d84022297a4c7d2bff8ce938'
            '19ae712fe9f4fb0ff1ba80c1a2ddc51ec5536687c78586eb975ce5c71573c6fc'
            'f1f0e6060b9c6ce6c37e77be3e056ec1657ae2fad661c59b9316b57bb3a0f777'
            'e55e470c9b02f75a9385a51308a9ef8bd7abe6e922bf8db7778239db5638c414')