# Maintainer (Arch): Eli Schwartz <eschwartz@archlinux.org>
# Contributor (Arch): Daniel Landau <daniel.landau@iki.fi>
# Contributor (Arch): Einhard Leichtfuß <alguien@respiranto.de>
# Contributor (Arch): Xyne
# Contributor (Arch): David Manouchehri <d@32t.ca>
# Contributor (Arch): Alexander Fehr <pizzapunk gmail com>
# Contributor (Arch): Thomas Jost <schnouki schnouki net>
# Contributor (Arch): Hinrich Harms <arch hinrich de>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=thunderbird-extension-enigmail
pkgname=icedove-extension-enigmail
pkgver=2.0.9
pkgrel=1
pkgdesc="OpenPGP message encryption and authentication for Icedove"
arch=('any')
url="https://www.enigmail.net/"
license=('MPL' 'GPL3')
makedepends=('zip' 'python2' 'perl')
replaces=($_pkgname 'icedove-enigmail')
conflicts=($_pkgname)
provides=($_pkgname)
source=("https://www.enigmail.net/download/source/enigmail-${pkgver}.tar.gz"{,.asc}
        "0001-preferences-disable-pEpAutoDownload-by-default.patch")
sha512sums=('2053148b0e5e763dfc1f8decff0fea2a40ebd306e4844440bd9a3ced4e1f7ff2f16bccf72f85e73b7c51b40629489ad125b9bc166558e3b4144038ba45fcb197'
            'SKIP'
            '4307c7b6bce7febba7a8186467c3bc93ec3428e1cd75cddad659e4d4a71832f1c8d46e4c811da38ff1dc38b1961a82bd84e7c90b7c63ce080be49ce69571c016')
validpgpkeys=('4F9F89F5505AC1D1A260631CDB1187B9DD5F693B') # Patrick Brunschwig <patrick@enigmail.net>

prepare() {
    cd "${srcdir}"/enigmail

    # Using vendor settings via /usr/lib/thunderbird/defaults/preferences/enigmail.js
    # does not seem to work.
    patch -p1 -i ../0001-preferences-disable-pEpAutoDownload-by-default.patch
}

build() {
    cd "${srcdir}"/enigmail

    ./configure
    # https://gitlab.com/enigmail/enigmail/merge_requests/34
    make -j1 XPI_MODULE_VERS=${pkgver} # fails with -j greater than 1
}

package() {
    depends=('icedove' 'gnupg')
    cd "${srcdir}"/enigmail

    if [[ -f package/install.rdf ]]; then
        _extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' build/dist/install.rdf)"
    else
        _extension_id="$(sed -n 's/.*"id": "\(.*\)".*/\1/p' build/dist/manifest.json)"
    fi
    _extension_dest="${pkgdir}/usr/lib/icedove/extensions/${_extension_id}"
    # Should this extension be unpacked or not?
    if grep -q '<em:unpack>true</em:unpack>' build/dist/install.rdf 2>/dev/null; then
        install -dm755 "${_extension_dest}"
        cp -R build/dist/* "${_extension_dest}"
        chmod -R ugo+rX "${_extension_dest}"
    else
        install -Dm644 build/enigmail-${pkgver}.xpi "${_extension_dest}.xpi"
    fi
}