# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Eschwartz <eschwartz93@gmail.com>

pkgname=iceweasel-noscript

pkgver=10.1.2
pkgrel=1
arch=(any)

pkgdesc="Extension for iceweasel which disables script"
url="https://noscript.net/"
license=(GPL)

depends=(iceweasel)
makedepends=(unzip)
replaces=(firefox-noscript)
groups=(iceweasel-addons)

source=(https://secure.informaction.com/download/releases/noscript-$pkgver.xpi)
noextract=("noscript-$pkgver.xpi")
sha256sums=('b9b8675746c5f02280c5fc403eae68999b059bd3c1f4f9fc952ba5764531aa0b')

prepare() {
  unzip -qqo "noscript-$pkgver.xpi" -d "noscript-$pkgver"
}

package() {
  _extension_id="$(sed -n '/.*"id": *"\(.*\)".*/{s//\1/p;q}' noscript-$pkgver/manifest.json)"
  _extension_dest="$pkgdir/usr/lib/iceweasel/browser/extensions/$_extension_id"

  # _extension_id must not be empty
  [ -n "$_extension_id" ] || (echo "error extracting extension_id" >&2 && exit 1)

  if grep '<em:unpack>true</em:unpack>' noscript-$pkgver/install.rdf > /dev/null; then
    install -dm755 "$_extension_dest"
    cp -R noscript-$pkgver/* "$_extension_dest"
    chmod -R ugo+rX "$_extension_dest"
  else
    install -Dm644 noscript-$pkgver.xpi "$_extension_dest.xpi"
  fi
}