# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

_pkgname=asm
pkgname=java-asm3
_pkgver=3
pkgver=3.3.1
pkgrel=4.1
pkgdesc="An all purpose Java bytecode manipulation and analysis framework."
arch=('any')
url="http://asm.ow2.org/"
license=('custom:BSD3')
depends=('java-runtime')
makedepends=(
  apache-ant
  java-ow-util-ant-tasks
)
source=("http://download.forge.objectweb.org/$_pkgname/$_pkgname-$pkgver.tar.gz")

_M2_LOCALREPO='/usr/share/maven/repository'
_ow_util_ant_tasks='/usr/share/java/ow_util_ant_tasks.jar'
_m2_packages=(
  asm
  asm-analysis
  asm-commons
  asm-parent
  asm-tree
  asm-util
  asm-xml
  asm-all
  asm-debug-all)

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  rm cobertura.ser # We regenerate this
  rm examples/jasmin/test/jasmin.jar

  echo "objectweb.ant.tasks.path $_ow_util_ant_tasks" >> build.properties
  ant dist

  # This will make package() easier:
  cd output/dist/lib
  ln -s all/* .
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  # Install license file
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # Install documentation
  cd output/dist
  install -d "$pkgdir/usr/share/doc/$pkgname"
  cp -r doc/javadoc/user "$pkgdir/usr/share/doc/$pkgname/javadoc"
  cp -r examples         "$pkgdir/usr/share/doc/$pkgname/examples"
  
  # Install Apache Maven modules
  cd lib
  install -d "$pkgdir"/usr/share/java/asm
  for pkg in "${_m2_packages[@]}"; do
    dir="$_M2_LOCALREPO"/asm/$pkg/$pkgver
    # Create the Maven directory
    install -d "$pkgdir$dir"
    # Install the files
    cp $pkg-$pkgver.* "$pkgdir$dir"
    # Symlink them to /usr/share/java
    ln -s "$dir"/$pkg-$pkgver.jar "$pkgdir"/usr/share/java/asm/
    ln -s asm/$pkg-$pkgver.jar "$pkgdir"/usr/share/java/$pkg-$_pkgver.jar
  done
  
  # Install a README file about the -all files
  cd "$srcdir/$_pkgname-$pkgver"
  install -m644 output/dist/lib/all/README.txt \
    "$pkgdir"/usr/share/java/asm/README-$pkgver.txt
}

md5sums=('433024df8176f09922646316e415631c')