# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=java-batik
pkgver=1.8
pkgrel=2.parabola1
pkgdesc='SVG library for Java.'
arch=('any')
url='http://xmlgraphics.apache.org/batik/'
license=(APACHE)
depends=('java-runtime' 'java-commons-io' 'java-commons-logging' 'java-xmlgraphics-commons'
         'java-xml-commons-external' 'rhino' 'xalan-java' 'xerces2-java')
makedepends=('java-environment' 'apache-ant' 'unzip' 'jh')
source=("https://www.apache.org/dist/xmlgraphics/batik/source/batik-src-${pkgver}.tar.gz"{,.asc}
        'batik-remove_js.patch')
md5sums=('2d330fce73c15629b9052a1a52d4af24'
         'SKIP'
         '71705a32991629bf5f8ee35c91c88dca')
validpgpkeys=('9D5F9D9B3E21B585E8F4551082036989D56B5F17') # Luis Bernardo

prepare() {
	cd "${srcdir}/batik-${pkgver}"
	rm -rv lib/*
	rm -rv test-resources/org/apache/batik/bridge/*.jar
	rm -rv documentation-sources/content/demo/*.jar
	ln -sf /usr/share/java/xml-apis.jar lib/xml-apis.jar
	ln -sf /usr/share/java/xml-apis-ext.jar lib/xml-apis-ext.jar
	#ln -sf /usr/share/java/xalan.jar lib/xalan.jar
	#ln -sf /usr/share/java/xercesImpl.jar lib/xercesImpl.jar
	ln -sf /usr/share/java/xmlgraphics-commons.jar lib/xmlgraphics-commons.jar

	patch -Np1 -i ../batik-remove_js.patch
}

build() {
	cd "${srcdir}/batik-${pkgver}"
	ant all-jar libs-jar ext-jar transcoder-jar maven-artifacts
}

package() {
	cd "${srcdir}/batik-${pkgver}/batik-${pkgver}"

	# Install license file
	install -Dm644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

	# Install Maven artifacts
	install -d "${pkgdir}/usr/share/java/batik"
	export DESTDIR=${pkgdir}
	for artifact in $(find . -name "*.pom" | sed 's/.*\///' | sed 's/-[0-9.]*\.pom$//'); do
	  jh mvn-install "org.apache.xmlgraphics" ${artifact} ${pkgver} \
	    "maven/${artifact}/${pkgver}/${artifact}-${pkgver}.pom" \
	    "maven/${artifact}/${pkgver}/${artifact}-${pkgver}.jar" \
	    "${artifact}.jar"

	  # Symlink them to /usr/share/java
	  ln -s "/usr/share/java/${artifact}.jar" \
	    "${pkgdir}/usr/share/java/${artifact}-${pkgver}.jar"
	done

	# Install batik-all.jar and batik-libs.jar
	install -m644 "lib/batik-all-${pkgver}.jar" \
	  "${pkgdir}/usr/share/java/batik/"
	install -m644 "lib/batik-libs-${pkgver}.jar" \
	  "${pkgdir}/usr/share/java/batik/"

	ln -s "/usr/share/java/batik/batik-all-${pkgver}.jar" \
	  "${pkgdir}/usr/share/java/batik/batik-all.jar"
	ln -s "/usr/share/java/batik/batik-libs-${pkgver}.jar" \
	  "${pkgdir}/usr/share/java/batik/batik-libs.jar"
}