# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=java-ow-util-ant-tasks
pkgver=1.3.2
pkgdesc="ObjectWeb utility Ant tasks library"
url="http://forge.ow2.org/projects/monolog"
license=('LGPL')

pkgrel=3
arch=('any')
depends=('java-environment')
makedepends=('apache-ant' 'xalan-java' 'java-asm2')

source=("libre://$pkgname-$pkgver.tar.gz")
md5sums=('f64b2aeac98508ac322a6509ba754425')

mksource=("http://download.forge.objectweb.org/monolog/ow_util_ant_tasks_$pkgver.zip")
mknoextract=("ow_util_ant_tasks_$pkgver.zip")
mkmd5sums=('cd602bf75a0feab480fa97739955b84e')
mksource() {
  cd "$srcdir"
  mkdir $pkgname-$pkgver
  cd $pkgname-$pkgver
  bsdtar xf ../ow_util_ant_tasks_$pkgver.zip
  rm -rf output
  rm externals/*
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ln -s /usr/share/java/asm-2.jar externals/
  ln -s /usr/share/java/xalan.jar externals/
  ant jar
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -d "$pkgdir"/usr/share/java
  install -m644 "output/lib/ow_util_ant_tasks.jar" "$pkgdir"/usr/share/java
}