# Maintainer (Arch): Guillaume ALAUX <Guillaume at Arch Linux dot org>
# Rationale: Arch version isn't built from source.
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=junit
pkgver=4.12
pkgrel=1.parabola1
pkgdesc='Simple JVM framework to write repeatable tests'
arch=('any')
url='http://www.junit.org/'
license=('EPL')
depends=('java-runtime' 'java-hamcrest')
makedepends=('apache-ant' 'jh')
source=("https://github.com/junit-team/${pkgname}/archive/r${pkgver}.tar.gz"
        "build.xml")
sha256sums=('61a16d8abf5a0d2d35a0c69a278e457a8b1f7b3726813c00c4775d39bce0dce4'
            'SKIP')

prepare() {
  cd "${srcdir}/${pkgname}-r${pkgver}"
  rm -rv lib/*.jar
  mv ../build.xml .
  ln -sf /usr/share/java/hamcrest-core.jar lib/hamcrest-core-1.3.jar
}

build() {
  cd "${srcdir}/${pkgname}-r${pkgver}"

  ant dist
}

package() {
  cd "${srcdir}/${pkgname}-r${pkgver}"

  # Install license file
  install -Dm644 LICENSE-junit.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"

  # Install documentation
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r "${pkgname}${pkgver}/javadoc" "${pkgdir}/usr/share/doc/${pkgname}"

  export DESTDIR="$pkgdir"
  jh mvn-install ${pkgname} ${pkgname} ${pkgver} \
    pom.xml \
    "${pkgname}${pkgver}/${pkgname}-${pkgver}.jar" \
    "${pkgname}.jar"

  ln -s "/usr/share/java/${pkgname}.jar" \
    "${pkgdir}/usr/share/java/${pkgname}-${pkgver}.jar"
}