# $Id: PKGBUILD 165921 2012-09-03 21:48:13Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=kdelibs
pkgname=kdelibs-libre
pkgver=4.9.1
pkgrel=1
pkgdesc="KDE Core Libraries"
arch=('i686' 'x86_64' 'mips64el')
url='https://projects.kde.org/projects/kde/kdelibs'
license=('GPL' 'LGPL' 'FDL')
depends=('strigi' 'attica' 'libxss' 'soprano' 'krb5' 'grantlee'
        'shared-desktop-ontologies' 'qca' 'libdbusmenu-qt' 'polkit-qt'
        'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr'
        'docbook-xsl' 'upower' 'udisks' 'libxcursor' 'phonon' 'qtwebkit'
        'media-player-info' 'libxtst')
makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'hspell')
provides=("kdelibs=$pkgver")
replaces=('kdelibs')
conflicts=('kdelibs')
install=${_pkgname}.install
source=("http://download.kde.org/stable/${pkgver}/src/${_pkgname}-${pkgver}.tar.xz"
        'kde-applications-menu.patch'
        'use-pythondontwritebytecode.patch'
        'khtml-fsdg.diff')
sha1sums=('33fb26ec7735122b2bb084b79f8fcffb826c58f0'
          '86ee8c8660f19de8141ac99cd6943964d97a1ed7'
          'bbacbbe2194f3961cd7557d98a9ddef158ca11aa'
          'a1502a964081ad583a00cf90c56e74bf60121830')

build() {
       cd "${srcdir}"/${_pkgname}-${pkgver}

       # avoid file conflict with gnome-menus
       patch -p1 -i "${srcdir}"/kde-applications-menu.patch

       # Set PYTHONDONTWRITEBYTECODE (KDEBUG#276151)
       patch -p0 -i "${srcdir}"/use-pythondontwritebytecode.patch
       
       # Don't ask the user to download a plugin, it's probably nonfree.
       patch -p1 -i "${srcdir}"/khtml-fsdg.diff

       cd "${srcdir}"
       mkdir build
       cd build
       cmake ../${_pkgname}-${pkgver} \
               -DCMAKE_BUILD_TYPE=Release \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Parabola GNU/Linux-libre' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF \
               -DWITH_HUpnp=OFF
       make
}

package() {
       cd "${srcdir}"/build
       make DESTDIR="${pkgdir}" install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
}