# $Id: PKGBUILD 188552 2013-06-15 11:11:13Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

pkgbase=kdenetwork
pkgname=('kdenetwork-kopete-libre')
pkgver=4.10.4
pkgrel=2
arch=('i686' 'x86_64' 'mips64el')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdenetwork')
makedepends=('cmake' 'automoc4' 'boost' 'speex' 'ortp' 'libotr3' 'ppp'
	'qca-ossl' 'kdebase-workspace' 'kdebase-lib' 'libvncserver'
    'v4l-utils' 'libidn' 'qimageblitz' 'libxdamage' 'libgadu' 'libmsn'
    'libktorrent' 'libmms' 'telepathy-qt')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.xz"
        'use-libotr3.patch')
sha1sums=('891277c8dcbf231452947e9b4c54324bad35fd1a'
          '9c3b0ee15538fbfa36aa0a4748b1f6b5a7905384')

prepare() {
    cd ${pkgbase}-${pkgver}
    patch -p1 -i "${srcdir}"/use-libotr3.patch
    cd ../
# Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
    sed -i 's/Skype protocol" ON/Skype protocol" OFF/g' "${pkgbase}-${pkgver}/kopete/protocols/CMakeLists.txt"
    rm -rf "${pkgbase}-${pkgver}/kopete/protocols/skype"
    sed 's/, Skype//' -i "${pkgbase}-${pkgver}/doc/kopete/index.docbook"
}

build() {
	mkdir build
	cd build
	cmake ../${pkgbase}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DKDE4_BUILD_TESTS=OFF \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DMOZPLUGIN_INSTALL_DIR=/usr/lib/mozilla/plugins/ \
		-DWITH_Xmms=OFF \
		-DWITH_LibMeanwhile=OFF \
		-DWITH_qq=OFF
	make
}

package_kdenetwork-kopete-libre() {
	pkgdesc='Instant Messenger, without skype support'
	depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr3' 'libmsn'
	         'libidn' 'qimageblitz' 'libgadu')
        conflicts=('kdenetwork-kopete')
        provides=("kdenetwork-kopete=${pkgver}")
        replaces=('kdenetwork-kopete')
	url="http://kde.org/applications/internet/kopete/"
	install='kdenetwork-kopete.install'
	cd $srcdir/build/kopete
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/kopete
	make DESTDIR=$pkgdir install
}