# $Id: PKGBUILD 201659 2013-12-17 13:52:43Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=kdenetwork-kopete
pkgname=kdenetwork-kopete-libre
pkgver=4.12.0
pkgrel=1
pkgdesc='Instant Messenger, without skype support'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdenetwork')
depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr' 'libmsn' 'libidn'
         'qimageblitz' 'libgadu' 'mediastreamer' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost')
install=${_pkgname}.install
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://download.kde.org/stable/${pkgver}/src/kopete-${pkgver}.tar.xz")
sha1sums=('c1ef611b27079388e48e558a65e2de80db93d875')

prepare() {
  cd kopete-${pkgver}
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  sed -i 's/Skype protocol" ON/Skype protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/skype
  sed 's/, Skype//' -i doc/index.docbook
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../kopete-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}