# $Id: PKGBUILD 266881 2016-05-04 20:12:28Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald.archlinux.org>
# Contributor (Arch): Damir Perisa <damir.perisa@bluewin.ch>
# Maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgname=kile
pkgver=2.1.3
pkgrel=7.parabola1
pkgdesc="A user friendly TeX/LaTeX frontend for KDE, without nonfree Adobe Reader recommendation"
arch=("i686" "x86_64" "armv7h")
license=('GPL2')
url="http://kile.sourceforge.net/"
depends=('kdebase-runtime' 'texlive-core' 'kdebase-katepart')
makedepends=('cmake' 'automoc4')
optdepends=('kdebase-konsole: embedded terminal')
conflicts=('kile-libre')
replaces=('kile-libre')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2"
        "libre.patch")
sha1sums=('1a80748d5f01f359b5e5c28140ec90691f0166c5'
          '9bbe5d1b0e2a78b13667fcf4e5e21f801447f9d6')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  # Remove nonfree Adobe Reader recommendation
  patch -Np1 -i "${srcdir}/libre.patch"
  cd ..
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}