# Maintainer (Arch:libffi):  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch:libffi): Stéphane Gaudreault <stephane@archlinux.org>
# Contributor (Arch:libffi): Jan de Groot <jgc@archlinux.org>
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

_pkgname=libffi
pkgname=libffi-static
pkgver=3.2.1
pkgrel=2.static2
pkgdesc='Portable foreign function interface library'
pkgdesc+=' (static libraries)'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='http://sourceware.org/libffi/'
license=('MIT')
depends=("libffi=$pkgver")
options=('staticlibs')
checkdepends=('dejagnu')
source=(ftp://sourceware.org/pub/libffi/libffi-$pkgver.tar.gz)
sha1sums=('280c265b789e041c02e5c97815793dfc283fb1e6')

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --disable-static \
    --disable-shared --enable-static \
    --enable-pax_emutramp
  make
}

check() {
  make -C $_pkgname-$pkgver check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE

  rm -vr -- \
     "$pkgdir/usr/lib"/libffi-*/ \
     "$pkgdir/usr/lib/pkgconfig/" \
     "$pkgdir/usr/share/info/" \
     "$pkgdir/usr/share/man/"
}