# $Id: PKGBUILD 191823 2016-10-10 10:17:01Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

_pkgname=libosinfo-libre
pkgname=libosinfo
pkgver=1.2.0
pkgrel=1.parabola1
pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support, without non-FSDG compliant distros and operating systems support"
arch=('i686' 'x86_64' 'armv7h')
url="https://libosinfo.org/"
license=('GPL' 'LGPL')
depends=('glib2' 'libxslt' 'osinfo-db')
makedepends=('check' 'gobject-introspection' 'intltool' 'libsoup' 'vala' 'gtk-doc')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
mksource=(https://releases.pagure.org/libosinfo/$pkgname-$pkgver.tar.gz{,.asc})
source=(https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-$pkgver.tar.gz
        libre.patch)
validpgpkeys=('DAF3A6FDB26B62912D0E8E3FBE86EBB415104FDF') # Daniel P. Berrange
mksha256sums=('ee254fcf3f92447787a87b3f6df190c694a787de46348c45101e8dc7b29b5a78'
              'SKIP')
sha256sums=('6abe6b8bb3fdfaf748751c24bec5fb446723505e799024fabde9f5ecb7102482'
            '896216d2f132ff772b3c0cd9e18aa6c45aca2365767fc0c3aa98e8d3a21ca063')

mksource() {
  cd $pkgname-$pkgver
  rm -rv {docs,tests/isodata/*}
}

prepare() {
  cd $pkgname-$pkgver
  sed -i '/export LC_ALL = C/d' maint.mk

#  rm -rv {docs,tests/isodata/*}

  patch -Np1 -i ../libre.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
              --with-pci-ids-path=/usr/share/hwdata/pci.ids \
              --enable-gtk-doc
  make
}

check() {
  cd $pkgname-$pkgver
  make check || :
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}