# $Id: PKGBUILD 191823 2016-10-10 10:17:01Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=libosinfo
pkgver=1.1.0
pkgrel=1.parabola2
pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support, without non-FSDG compliant distros and operating systems support"
arch=('i686' 'x86_64' 'armv7h')
url="http://libosinfo.org/"
license=('GPL' 'LGPL')
depends=('glib2' 'libxslt' 'osinfo-db')
makedepends=('check' 'gobject-introspection' 'intltool' 'libsoup' 'vala' 'gtk-doc')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
options=('!libtool')
source=(https://releases.pagure.org/libosinfo/$pkgname-$pkgver.tar.gz{,.asc}
        libre.patch)
validpgpkeys=('DAF3A6FDB26B62912D0E8E3FBE86EBB415104FDF') # Daniel P. Berrange
sha256sums=('600f43a4a8dae5086a01a3d44bcac2092b5fa1695121289806d544fb287d3136'
            'SKIP'
            '55f4dad4a25b9235174ed858f4b86c689c0c10e6cc29231e5a4598f42af6b4b2')

prepare() {
  cd $pkgname-$pkgver
  sed -i '/export LC_ALL = C/d' maint.mk

  rm -rv {docs,tests/isodata/*}

  patch -Np1 -i ../libre.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
              --with-pci-ids-path=/usr/share/hwdata/pci.ids \
              --enable-gtk-doc
  make
}

check() {
  cd $pkgname-$pkgver
  # Fails on test-isodetect
  # make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}