# $Id: PKGBUILD 100489 2013-11-05 09:06:26Z bpiotrowski $
# Maintainer: Federico Cinelli <cinelli@aur.archlinux.org>
# Maintainer: Mateusz Herych   <heniekk@gmail.com>
# Contributor (Parabola): Jorge Lopez <jorginho@lavabit.com>

pkgname=libquicktime-libre
_pkgname=libquicktime
pkgver=1.2.4
pkgrel=8
pkgdesc="A library for reading and writing quicktime files, without nonfree faac support"
arch=('i686' 'x86_64')
license=('GPL')
url="http://libquicktime.sourceforge.net/"
depends=('gtk2' 'ffmpeg' 'libxv' 'libxaw' 'faad2')
makedepends=('mesa-libgl')
source=("http://downloads.sourceforge.net/sourceforge/$_pkgname/$_pkgname-$pkgver.tar.gz"
        ffmpeg2.0.patch)
sha256sums=('1c53359c33b31347b4d7b00d3611463fe5e942cae3ec0fefe0d2fd413fd47368'
            'a1c8415e8e7bc04c81b946b9e3746f7d5ef24819135962280c3a7ddb3f2baa2b')
provides=("$_pkgname=$pkgver")
conflicts=($_pkgname)
replaces=($_pkgname)

prepare() {
  cd $_pkgname-$pkgver
  patch -Np1 -i ../ffmpeg2.0.patch
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure --prefix=/usr \
  	--enable-gpl \
	--with-ffmpeg \
	--with-x264 \
	--without-doxygen
	make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}