# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@lavabit.com>

pkgbase=libretools
pkgname=(libretools libretools-mips64el librelib)
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/packages/libretools.git/"
license=('GPL3' 'GPL2')

pkgver=20130627
_libretools_commit=08375ed421d18b48388169c7fc7cf4ca076577ba
_devtools_commit=bf8513ae631484a0c292ad085ea7ede9859f8e0f

_packages_url=https://projects.parabolagnulinux.org/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
	$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)

pkgrel=1
arch=('any')
makedepends=(emacs) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup)

build() {
  cd "$srcdir"
  ln -sf devtools-par-$_devtools_commit devtools-par
  cd "$srcdir/$pkgbase-$_libretools_commit"
  make build-libretools build-libretools-mips64el build-librelib build-doc
}

check() {
  cd "$srcdir/$pkgbase-$_libretools_commit"

  make check TESTENVFLAGS='--no-network --no-sudo'
}

package_librelib() {
  pkgdesc="Shell library portion of libretools"
  depends=(
    wget # `aur` and `lib/blacklist.sh`
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-librelib DESTDIR="$pkgdir"
}

package_libretools() {
  backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
  install=libretools.install
  replaces=(chroottools)
  conflicts=(devtools)

  depends=(
    "librelib=$pkgver"
    arch-install-scripts # `archroot` uses `pacstrap`
    git # `createworkdir` (also mips-add in -mips64el)
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    subversion # `diff-unfree`
    tokyocabinet # `treepkg`
  )
  optdepends=('namcap: to check package files')

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools install-doc DESTDIR="$pkgdir"
}

package_libretools-mips64el() {
  pkgdesc="Scripts for Parabola development (for mips64el architecture)"
  depends=("$pkgbase=$pkgver")

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}

md5sums=('acbdcd22c1b922f943651dbf7c320bbd'
         'b28b1492fda205be7c577fc03cbc3399')